Fix graph size and automatically adjust canvas

Question

I would like to produce many different figures for my thesis, which should visually look consistent to each other. I.e. I want the graph size (the visible border) of each plot to have the same size. My challenge is that (x/x2/y/y2)tics and labels are sometimes present, sometimes not. A rather crude approach would be to use a fixed canvas size and fixed margins, but this would give undesirably large empty space above and below the plot if x or x2 tics and labels are absent.

I will be using the cairolatex terminal. Is there a possibility to fix the graph size, but to allow autoscaling of the canvas? Some pseudo-code would be:

# desired graph size in cm
graph_width = 10
graph_height = 7
# calculate extra space that is needed for tics and labels
extra_space_bottom = 0
if [xtics = on]
 extra_space_bottom = extra_space_bottom + <space for xtics>
if [xlabel = on]
 extra_space_bottom = extra_space_bottom + <space for xlabel>
# ...
# the same for y, x2, y2, title, colorbox etc.
# now the canvas size will be:
set terminal cairolatex size graph_width+extra_space_left+extra_space_right, graph_height+extra_space_bottom+extra_space_top

Maybe this could be a starting point?

Answer 1

Amended answer using \input{figure} rather than generating a standalone figure for inclusion

After looking at the source code and playing with set term tikz plotsize x,y I have concluded that this option was not well thought out and cannot easily be fixed. However there is a different tikz option tightboundingbox that seems to do exactly what you want and requires no source code modification.

My suggestion:

(1) Define a fixed size output in gnuplot's set term command, and define fixed plot borders within that leaving sufficient space in the margins for the most space-consuming labels you expect to handle. This amended answer requires the tikz terminal because we will use the tightboundingbox terminal option

 set term tikz tightboundingbox size 5in, 3in
 set output 'figure_N.tex'
 set lmargin at screen 0.15
 set rmargin at screen 0.85
 set tmargin at screen 0.85
 set bmargin at screen 0.15

(2) Plot your figures and close the output TeX file

 set output 'figure_1.tex'
 plot <whatever>
 set output 'figure_2.tex'
 plot <something else>
 unset output

(3) In your TeX document, do not give it the original size specified in set term. Let it pick up the bounding box as calculated by tikz/pgf. E.g.

\usepackage{gnuplot-lua-tikz}
\usepackage{wrapfig}
\begin{document}

Some text\\

\begin{wrapfigure}{r}{}
\input{figure_1}
\end{wrapfigure}

Some more text\\

\begin{wrapfigure}{r}{}
\input{figure_2}
\end{wrapfigure}

Yet more text\\
\end{document}

Answer 2

This is a straightforward question, however, I'm not sure if there is a simple way to do it in gnuplot. I thought I've seen a similar question earlier, but I can't find it. At least, gnuplot has the option to set the aspect ratio of a graph, check help size. With this the graph will have the desired aspect ratio and eventually extra wide margins either on the left and right or on top and bottom, depending on the canvas aspect ratio.

The idea of this workaround is the following;

1. set the aspect ratio of your graph to the desired ratio GraphSizeFixedY/GraphSizeFixedX.
2. set your canvas to the size GraphSizeFixedX, GraphSizeFixedY, plot the graph and remember the margins (left, right, bottom, top)
3. set your canvas to the "inverse" aspect ratio GraphSizeFixedY, GraphSizeFixedX, replot and remember the margins
4. set the canvas to the desired width and height and add the minimum of the remembered corresponding margins and replot again.

Drawback is that you have to plot 3 times. I tried this for wxt and pdfcairo terminal. I hope it will also work for pdflatex terminal. Maybe there is an easier solution which I haven`t thought of.

Code:

### fixed graph size and variable canvas size
reset session

myTerminal = 'wxt'
GraphSizeFixedX = 500
GraphSizeFixedY = 350
Unit = ''

# uncomment these lines if you want to use pdfcairo terminal
# myTerminal = 'pdfcairo'
# GraphSizeFixedX = 10
# GraphSizeFixedY = 7
# Unit = 'cm'

FILE = 'tbSizeGraphFixed.pdf'
set output FILE

set size ratio real(GraphSizeFixedY)/GraphSizeFixedX   # real() to avoid integer division

LMargin(n) = GPVAL_TERM_XMIN
RMargin(n) = GPVAL_TERM_XSIZE/GPVAL_TERM_SCALE+1-GPVAL_TERM_XMAX
BMargin(n) = GPVAL_TERM_YMIN
TMargin(n) = GPVAL_TERM_YSIZE/GPVAL_TERM_SCALE+1-GPVAL_TERM_YMAX

# set canvas ratio
set term @myTerminal size GraphSizeFixedX @Unit, GraphSizeFixedY @Unit

# actual plotting command
set xlabel "x-label"
set ylabel "y-label"
# set x2label "x2-label"    # uncomment for comparison
# set y2label "y2-label"    # uncomment for comparison
plot sin(x)

Lmargin1 = LMargin(0)
Rmargin1 = RMargin(0)
Bmargin1 = BMargin(0)
Tmargin1 = TMargin(0)

# set "inverse" canvas ratio
set term @myTerminal size GraphSizeFixedY @Unit, GraphSizeFixedX @Unit
replot
Lmargin2 = LMargin(0)
Rmargin2 = RMargin(0)
Bmargin2 = BMargin(0)
Tmargin2 = TMargin(0)

min(a,b) = a<b ? a : b
Factor = myTerminal eq "wxt" ? 1: GPVAL_TERM_SCALE    # not completely clear why this is needed

TermSizeVarX = GraphSizeFixedX + \
               real(min(Lmargin1,Lmargin2) + min(Rmargin1,Rmargin2)) / Factor
TermSizeVarY = GraphSizeFixedY + \
               real(min(Bmargin1,Bmargin2) + min(Tmargin1,Tmargin2)) / Factor

set term @myTerminal size TermSizeVarX @Unit, TermSizeVarY @Unit
set output FILE
replot

set output
### end of code

Result: (wxt terminal, graph size 500,350 pixels, background colored just for illustration)

x and y-label only. Canvas size 586 x 418 pixels

x,y,x2, and y2-label. Canvas size 610 x 434 pixels

Answer 3

Based on the approach of @theozh I found a way to correctly calculate the canvas size. The idea is to let gnuplot automatically handle the margins, measure their size, add them to the total canvas size and replot. Fortunately the size of margins is "constant", i.e. the tic labels and axis labels always take the same amount of space no matter how large the terminal size is.

1. plot everything with cairolatex with some initial guess for the size
2. from the internal variables GPVAL_TERM_* read the size of the margins
3. add the calculated margins to the size and replot.

The same procedure will also work if some of the margins are set by the user.

Note: Not tested for multicolumn key placed outside the graph

### fixed graph size and variable canvas size
reset session

myTerminal = 'cairolatex'
XSize = 10 #cm
YSize = 7 #cm

set term @myTerminal size XSize cm, YSize cm
FILE = 'tbSizeGraphFixed.tex'
set out FILE

# actual plotting command
set xlabel "x-label"
set ylabel "y-label"
plot sin(x)

# cairolatex is calculating the size in bp, convert it to cm.
# _*MIN and _*MAX are the borders of the graph
# _*SIZE is canvas size, scaled by _SCALE
# for whatever reason, _*SIZE is 1bp smaller than the actual canvas, and is scaled by a factor of 20
bp2cm = 0.03528
LSpace = bp2cm * (GPVAL_TERM_XMIN)
RSpace = bp2cm * (GPVAL_TERM_XSIZE/GPVAL_TERM_SCALE -GPVAL_TERM_XMAX +1)
BSpace = bp2cm * (GPVAL_TERM_YMIN)
TSpace = bp2cm * (GPVAL_TERM_YSIZE/GPVAL_TERM_SCALE -GPVAL_TERM_YMAX +1)

unset out
set term myTerminal size (XSize+LSpace+RSpace) cm, (YSize+BSpace+TSpace) cm
set out FILE
replot
unset out