tell iTerm to open several ssh session

Question

I've used some neat example's from attached URL's. What I've got so far is the script opening several tab's with ssh session's. But as I've several client's to whom's server's I connect I don't want a script with a hard coded list for every client. I want a dialod box asking to which list I'ld like to connect...

But now that I tried to add a dialog I'm stuck:

--set wseServer to {"xen", "bcs", "db", "lx", "mgr", "nx", "proxy", "smb", "wiki", "zarafa"} as list
set wseServer to paragraphs of (do shell script "/bin/cat $HOME/.ssh/hostlist-wse-deb.pssh")
--set edlServer to {"edl", "edev", "edb", "emon"}
set edlServer to paragraphs of (do shell script "/bin/cat $HOME/.ssh/hostlist-edl.pssh")
set allServer to wseServer & edlServer

set serverList to button returned of (display dialog "Dude, choose your prefered connection List" buttons {"wseServer", "edlServer", "allServer"} with title "SSH Server" default button 3 with icon caution giving up after 5)

tell application "iTerm"
activate
set myTerm to (make new terminal)
tell myTerm
    repeat with hostItem in serverList
        set Lsession to (make new session)
        tell Lsession
            --set secureshell to hostItem exec command "ssh " & hostItem
            exec command "ssh " & hostItem
            --sleep to prevent errors if we spawn too fast
            do shell script "/bin/sleep 0.01"
        end tell
    end repeat
end tell
end tell

After choosing one of the items from the dialog iterm opens 8 Tabs, doesnt execute ssh and closes them... No error no nothing!

This is the example I'm trying to expand: http://code.google.com/p/iterm2/wiki/AppleScript

I know I'm nearly there but can't see the solution!

Hope one of you has a hint...

Thx in advance

score 1 · Answer 1 · answered Jul 21 '13 at 20:30

This could be useful: https://raw.github.com/luismartingil/scripts/master/iterm_launcher02.applescript

#!/usr/bin/osascript
-- Applescript to launch iterm2 terminals/tabs with configurable:
-- ~ List of commands <cmds>
-- ~ Color <color>
-- ~ Name <name>
-- ~ Transparency <trans>
-- ~ Zoom out <zoomout>
-- ~ Split behavior horizontal(h) or vertical(v) <split> :: (h, v)
--
-- Run from terminal with `osascript` or just ./<<script>>
-- Dont unfocus with the mouse/keyboard while executing. the script.
-- Recomended to go full screen (CMD + Enter) if <zoomout> attributes used.
-- Change myTermWindow and myItem(s) as desired.
--
--
-- Author: Luis Martin Gil http://www.luismartingil.com
-- Year : 2013

tell application "iTerm"

    -- First tab
    set myItem1 to {}
    set myItem1 to myItem1 & {{color:"yellow", cmds:{"echo yellow", "ls -lrt"}, name:"name_yellow", trans:"0.1", zoomout:4, split:"h"}}
    set myItem1 to myItem1 & {{color:"blue", cmds:{"echo blue1", "ls -lrt"}, name:"name_blue1", trans:"0.1", zoomout:2, split:"v"}}
    set myItem1 to myItem1 & {{color:"blue", cmds:{"echo blue2", "ls -lrt"}, name:"name_blue2", trans:"0.1", zoomout:4, split:"v"}}
    set myItem1 to myItem1 & {{color:"blue", cmds:{"echo blue3", "ls -lrt"}, name:"name_blue3", trans:"0.1", zoomout:6}}

    -- Second tab   
    set myItem2 to {}
    set myItem2 to myItem2 & {{color:"red", cmds:{"echo red1", "ls -lrt"}, name:"name_red1", trans:"0.1", zoomout:8, split:"h"}}
    set myItem2 to myItem2 & {{color:"red", cmds:{"echo red2", "ls -lrt"}, name:"name_red2", trans:"0.1", zoomout:4}}

    -- Third tab
    set myItem3 to {}
    set myItem3 to myItem3 & {{color:"green", cmds:{"echo green", "ls -lrt"}, name:"name_green", trans:"0.1", zoomout:2, split:"v"}}
    set myItem3 to myItem3 & {{color:"purple", cmds:{"echo purple", "ls -lrt"}, name:"name_purple", trans:"0.1", zoomout:4}}

    set myTermWindow to {myItem1, myItem2, myItem3}

    set myterm to (make new terminal)

    tell myterm
        repeat with n from 1 to count of myTermWindow
            launch session n
            repeat with i from 1 to count of (item n of myTermWindow)
                -- Lets set the properties of the actual tab
                tell the last session to set name to name of (item i of (item n of myTermWindow))
                tell the last session to set background color to color of (item i of (item n of myTermWindow))
                tell the last session to set transparency to trans of (item i of (item n of myTermWindow))
                -- Some commands might require more columns to be readable
                repeat zoomout of (item i of (item n of myTermWindow)) times
                    tell i term application "System Events" to keystroke "-" using command down
                end repeat
                -- Lets execute the commands for the tab
                repeat with cmd in cmds of (item i of (item n of myTermWindow))
                    tell the last session to write text cmd
                end repeat
                -- Split the pane in a "D" (vertical) or "d" (horizontal) way
                if i is less than (count of (item n of myTermWindow)) then
                    if "h" is split of (item i of (item n of myTermWindow)) then
                        set split_str to "D"
                    else if "v" is split of (item i of (item n of myTermWindow)) then
                        set split_str to "d"
                    else
                        error
                        return
                    end if
                    tell i term application "System Events" to keystroke split_str using command down
                end if
            end repeat
        end repeat
    end tell
end tell

score 1 · Accepted Answer · answered Mar 28 '12 at 08:15

Answer to myself so it hopefully will help other's too:

removed all the stuff above the "tell application ..." and added this:

set sshList to {"WSE", "EDL", "Alle"}
set sshServer to choose from list sshList with title "SSH Server"
if sshServer = {"WSE"} then set serverList to paragraphs of (do shell script "/bin/cat $HOME/.ssh/hostlist-wse-deb.pssh")
if sshServer = {"EDL"} then set serverList to paragraphs of (do shell script "/bin/cat $HOME/.ssh/hostlist-edl.pssh")
if sshServer = {"Alle"} then set serverList to paragraphs of (do shell script "/bin/cat $HOME/.ssh/hostlist-wse-deb.pssh & /bin/cat $HOME/.ssh/hostlist-edl.pssh")

The dialog is not as beatyful as with the first attempt but it work's...

tell iTerm to open several ssh session

2 Answers2