Why does @array ~~ LIST return false even though @array contains the same elements as LIST?

Question

I have

@a = (1,2,3); print (@a ~~ (1,2,3))

and

@a = (1,2,3); print (@a == (1,2,3))

The first one is the one I expect to work, but it does not print anything. The second one does print 1.

Why? Isn't the smart matching operator ~~ supposed to match in the case of @a ~~ (1,2,3)?

`use strict; use warnings;` : *Useless use of a constant (2) in void context* — Quentin, Feb 24 '12 at 20:25
@Quentin: i am a little confused: why the context is void in `@a~~(1,2,3)`, and how can I force it to be in an array context? — Qiang Li, Feb 24 '12 at 20:42
The second one works by accident. Try `@a=(4,5,6);print (@a==(4,5,6))` instead. — mob, Feb 24 '12 at 20:52
@mob: by what accident? And what is the logic behind yours `@a=(4,5,6);print (@a==(4,5,6))`? Thank you. — Qiang Li, Feb 24 '12 at 20:53
@LightnessRacesinOrbit — No, as Jim said in his answer, it is a list. — Quentin, Feb 24 '12 at 20:53
In scalar context, an array is evaluated as its size. In scalar context, a list as evaluated as its last element. Your second example is equivalent to `print (3==3)`, but you should be clear where the `3` on each side of the equation comes from. In my `(4,5,6)` example, the expression is equivalent to `print (3==6)`. — mob, Feb 24 '12 at 21:12
@mob: thank you for the explanation. But why the warning message says `in void context`? — Qiang Li, Feb 24 '12 at 21:14
@Qiang Li - Try `perl -Mdiagnostics -e '@a=(1,2,3);print @a~~(1,2,3)'` — mob, Feb 24 '12 at 21:21
@Quentin: Indeed. I was making the point in the form of a question. — Lightness Races in Orbit, Feb 24 '12 at 23:19
@QiangLi: Lists and arrays are distinct. The latter may be initialised from the former. — Lightness Races in Orbit, Feb 24 '12 at 23:19
@Qiang Li, Perl knows you are discarding the result of the expressions `1` and `2`, so it evaluates them in void context. — ikegami, Feb 25 '12 at 01:57
@Qiang Li, There's no such thing as array context. You want (a reference to) an array, which has nothing to do with the context in which some list is evaluated anyway. — ikegami, Feb 25 '12 at 01:58
This is a perfectly good question. Smartmatch is just plain confusing. — Alex, Feb 25 '12 at 03:38

score 12 · Accepted Answer · answered Feb 25 '12 at 01:44

12

For a second, lets consider the slightly different

\@a ~~ (1,2,3)

~~ evaluates its arguments in scalar context, so the above is the same as

scalar(\@a) ~~ scalar(1,2,3)

\@a (in any context) returns a reference to @a.
1, 2, 3 in scalar context is similar to do { 1; 2; 3 }, returning 3.

So minus a couple of warnings*, the above is equivalent to

\@a ~~ 3

What you actually want is

\@a ~~ do { my @temp = (1,2,3); \@temp }

which can be shortened to

\@a ~~ [ 1,2,3 ]

Finally, the magic of ~~ allows \@a to be written as @a, so that can be shortened further to

@a ~~ [ 1,2,3 ]

* — Always use use strict; use warnings;!

answered Feb 25 '12 at 01:44

ikegami

367,544
15
269
518

1

I'd remove my answer, but it illustrates a step in my learning process. I aspire to one day reach your level of understanding. – Jim Davis Feb 25 '12 at 02:56
1

You can _edit_ your answer to represent additional steps in your learning process :) – brian d foy Feb 25 '12 at 16:59

Jim Davis · Answer 2 · 2012-02-24T22:13:08.543

9

Smart match tries to do what I think you're expecting if you use an array or an array reference on the right side -- but not a list.

$ perl -E '@a = (1, 2, 3); say (@a ~~ (1, 2, 3))'

$ perl -E '@a = (1, 2, 3); say ((1, 2, 3) ~~ @a)' # also misguided, but different
1
$ perl -E '@a = (1, 2, 3); say (@a ~~ [1, 2, 3])'
1

edited Feb 24 '12 at 22:13

answered Feb 24 '12 at 20:23

Jim Davis

5,241
1
26
22

5

Your second example is equivalent to `say 3~~@a`. You'll find that `say ((3,2,1)~~@a)` also prints 1, as does `say ((9,8,7,6,5,4,3,2,1)~~@a)`. – mob Feb 24 '12 at 20:59
Oh, wow. Evaluates as the last item in the list, then does a `scalar ~~ array` "smart" match? – Jim Davis Feb 24 '12 at 22:12
5

It's always `scalar ~~ scalar`. `@a` is simply a shortcut for `\@a`. – ikegami Feb 25 '12 at 01:26

brian d foy · Answer 3 · 2012-02-25T01:53:35.207

Start with What is the difference between a list and an array? in the perlfaq. It specifically shows you how your choice of values is wrong.

You might also start by writing out why you expected each to work or not work, so that we might correct your expectations. Why did you think you'd get the results that you expected?

As for the smart match bits, there's no rule for ARRAY ~~ LIST. The smart match only works with the pairs enumerated in its table in perlsyn. It's going to force it to be one of those pairs.

When you run into these problems, try many more cases:

#!perl
use v5.10.1;
use strict;
use warnings;

my @a = (1,2,3);
say "\@a is @a";
say "\@a ~~ (1,2,3) is ", try( @a ~~ (1,2,3) );
say "\@a ~~ [1,2,3] is ", try( @a ~~ [1,2,3] );
say "\@a ~~ 3 is ", try( @a ~~ 3 );
say "3 ~~ \@a is ", try( 3 ~~ @a );

say '';

my @b = (4,5,6);
say "\@b is @b";
say "\@b ~~ (4,5,6) is ", try( @b ~~ (4,5,6) );
say "\@b ~~ [4,5,6] is ", try( @b ~~ [4,5,6] );
say "\@b ~~ 3 is ", try( @b ~~ 3 );
say "3 ~~ \@b is ", try( 3 ~~ @b );

say '';
say "\@b ~~ \@a is ", try( @b ~~ @a );

sub try { $_[0] || 0 }

The output of the various cases is the clue that you misread the docs:

Useless use of a constant (2) in void context at test.pl line 8.
Useless use of a constant (4) in void context at test.pl line 17.
Useless use of a constant (5) in void context at test.pl line 17.
@a is 1 2 3
@a ~~ (1,2,3) is 0
@a ~~ [1,2,3] is 1
@a ~~ 3 is 0
3 ~~ @a is 1

@b is 4 5 6
@b ~~ (4,5,6) is 0
@b ~~ [4,5,6] is 1
@b ~~ 3 is 0
3 ~~ @b is 0

@b ~~ @a is 0

Why does @array ~~ LIST return false even though @array contains the same elements as LIST?

3 Answers3