Flex arraycollection getitemindex always return -1

Question

I'm facing the same problem. Can some explain me with a example?

My code is:

var dataList:ArrayCollection = new ArrayCollection([{name:"alauddn"}, {name:"ansari"}]);

private function getItemInd(event:MouseEvent):void{

    var item:Object = new Object();
    item.name = "ansari";
    var ias:int = dataList.getItemIndex(item);
    Alert.show(ias.toString() + ": " + item.name);
}

But it returns "-1:

Check out this Adobe blog: http://blogs.adobe.com/actionscriptdocs/2009/05/dataprovidergetitemindex.html — Alexander Farber, Aug 19 '13 at 15:18

score 8 · Answer 1 · answered Dec 21 '11 at 05:30

getItemIndex is not comparing the value within your arrayCollection. The problem is that the getItemIndex() method matches exact object references, not objects with matching properties.

You should use a solution like this instead :

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
    xmlns:s="library://ns.adobe.com/flex/spark" 
    xmlns:mx="library://ns.adobe.com/flex/mx" creationComplete="creationCompleteHandler(event)">

    <fx:Script>
        <![CDATA[
            import mx.collections.ArrayCollection;
            import mx.controls.Alert;
            import mx.events.FlexEvent;

            public var dataList:ArrayCollection = new ArrayCollection([{name:"alauddn"}, {name:"ansari"}]);

            public function getItemIndexByProperty(array:ArrayCollection, property:String, value:String):Number
            {
                for (var i:Number = 0; i < array.length; i++)
                {
                    var obj:Object = Object(array[i])
                    if (obj[property] == value)
                        return i;
                }
                return -1;

                dataList.getItemIndex();
            }

            protected function creationCompleteHandler(event:FlexEvent):void
            {
                var ias:int = getItemIndexByProperty(dataList, "name", "ansari");
                Alert.show(ias.toString() + " : " + dataList.getItemAt(ias).name);
            }

        ]]>
    </fx:Script>

</s:WindowedApplication>

Besides, if you only want to store key-values informations, I strongly suggest you to use a dictionary or, at least, a dynamic object. — LoremIpsum, Dec 21 '11 at 10:42

score 0 · Answer 2 · answered Dec 21 '11 at 05:16

getItemIndex only searches the root object. So for example this would work:

var dataList:ArrayCollection = new ArrayCollection(["alauddn", "ansari"]);

private function getItemInd(event:MouseEvent):void{
    var name:String = "ansari";
    var ias:int = dataList.getItemIndex(name);
    Alert.show(ias.toString() + ": " + name);
}

Santhosh Nayak · Answer 3 · 2011-12-21T09:03:36.140

0

You can use this.

private function getItemInd(event:MouseEvent):void{
for each( var item:Object in dataList){    
if(item.name == "ansari")
{
var ias:int = dataList.getItemIndex(item);
Alert.show(ias.toString() + ": " + item.name);
break;
}
}
}

edited Dec 21 '11 at 09:03

answered Dec 21 '11 at 05:30

Santhosh Nayak

2,312
3
35
65

Flex arraycollection getitemindex always return -1

3 Answers3