Converting New With from C# to VB.NET - Compilation Error

Question

I have the following code in C#:

public static ArrayList GetGenders()
{
    return new ArrayList()
    {
        new { Value = 1, Display = "ap" },
        new { Value = 2, Display = "up" }
    };
}

It's working fine. However, when I converted it to VB.NET:

Public Shared Function GetGenders() As ArrayList
    Return New ArrayList() From { _
        New With { _
            .Value = 1, _
            .Display = "ap" _
        }, _
        New With { _
            .Value = 2, _
            .Display = "up" _
        } _
    }
End Function

I get the following compile-time error:

BC30205: End of statement expected.

What's the problem with the code?

Define "it's not working." Do you get an error? Compile-time or run-time? — David, Dec 19 '11 at 18:31

score 3 · Answer 1 · edited Dec 19 '11 at 18:54

3

My psychic debugging skills tell me that you're using VB.Net 2005, which does not support anonymous types.

edited Dec 19 '11 at 18:54

Tim Schmelter

450,073
74
686
939

answered Dec 19 '11 at 18:43

SLaks

868,454
176
1,908
1,964

s iam using vb.net 2005.so no solution? – satish Dec 19 '11 at 19:10
You can create a named class, or you can use a later version. – SLaks Dec 19 '11 at 19:11
Or use a `List(of ListItem)`. – Tim Schmelter Dec 19 '11 at 19:52
@TimSchmelter: That won't help replace the anonymous type. – SLaks Dec 19 '11 at 20:08
@Slaks: Not all anonymous types, but maybe this specific case where he needs a type with a property `Value` and a property `Display`. Why should he create a new class when it's already existing? – Tim Schmelter Dec 19 '11 at 20:21

score 0 · Answer 2 · answered Jan 28 '14 at 20:18

0

lista.Add(New InvValorMedio With {.Data_Base = _dataBase, _
                                  .Tipo = item.IdInvTipo, _
                                  .Valor = 0})

answered Jan 28 '14 at 20:18

user3246175

11
1

2

If this is an answer, please add some description – user1781290 Jan 28 '14 at 20:39

score 0 · Answer 3 · answered Dec 19 '11 at 18:55

0

Its possible that this is a version of VB.Net prior to 2010, in which case the FROM syntax isn't available (I had the same issue earlier with some code converted by developerfusion - I was going from C# in .Net 4 to VB.Net in .Net 3.5)

The following 2 stage process should do it - not found a way of making it a single line yet:

Dim arr() = { _
    New With {.Value = 1, .Display = "ap"}, _
    New With {.Value = 2, .Display = "up"} _
}
return = New ArrayList(arr)

answered Dec 19 '11 at 18:55

Jon Egerton

40,401
11
97
129

1

Correction: According to comments this is in .Net 2, in which case the above anonymous types aren't available. However I'm leaving the answer up for reference for other users having problems with `FROM` – Jon Egerton Dec 19 '11 at 18:58

score 0 · Answer 4 · answered Dec 19 '11 at 19:47

A VB2005-specific answer involves creating a class to hold the values, then populating the arraylist with instances of the class.

The class:

Public Class LookupList
    Private m_Value As Integer
    Private m_sDisplay As String

    Public Sub New()
        MyBase.New()
    End Sub
    Public Sub New(ByVal wValue As Integer, ByVal sDisplay As String)
        Me.New()
        Me.Value = wValue
        Me.Display = sDisplay
    End Sub

    Public Property Value() As Integer
        Get
            Return m_Value
        End Get
        Set(ByVal value As Integer)
            m_Value = value
        End Set
    End Property
    Public Property Display() As String
        Get
            Return m_sDisplay
        End Get
        Set(ByVal value As String)
            m_sDisplay = value
        End Set
    End Property
End Class

And the method:

Public Shared Function GetGenders() As ArrayList
    Dim oList As New ArrayList
    oList.AddRange(New LookupList() {New LookupList(1, "ap"), New LookupList(2, "up")})
    Return oList
End Function

A solution that is slightly more inline with the original C# code is to create a collection class for the class:

Public Class LookupListCollection
    Inherits System.Collections.Generic.List(Of LookupList)

    Public Sub New()
        MyBase.New()
    End Sub
    Public Sub New(ByVal ParamArray aItems As LookupList())
        Me.New()
        If aItems IsNot Nothing Then
            Me.AddRange(aItems)
        End If
    End Sub

End Class

which can then be called as:

Public Shared Function GetGenders() As LookupListCollection
    Return New LookupListCollection(New LookupList(1, "ap"), New LookupList(2, "up"))
End Function

Converting New With from C# to VB.NET - Compilation Error

4 Answers4