using hitTestPoint() with stage object to create object boundaries

Question

I'm trying to create a boundary for a player object, controlled with arrow keys, in my game using the main stage's height and width. For example, one test point is at the top edge of the player object's bounding box so that when the player object's head touches the stage's top edge, the player can't move anymore to the north. The player object is manually instantiated to the center of the stage by using the Flash stage editor so it will start at the center before the program starts.

The problem is that right at the start of the program, I can no longer move the player object up or down with the arrow keys but I can still move it left or right. The intention is to allow the player to move north until the player object's head touches the top edge of the main stage. Here's the code:

package 
{
        public class Main_Playground extends MovieClip
        {
        var vx:int;
        var vy:int;

        public function Main_Playground()
        {
            init();
        }
        function init():void
        {
            //initialize variables
            vx = 0;
            vy = 0;

            //Add event listeners
            stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
            stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
        }

        function onKeyDown(event:KeyboardEvent):void
        {
            if (event.keyCode == Keyboard.LEFT)
            {
                vx = -5;
            }
            else if (event.keyCode == Keyboard.RIGHT)
            {
                vx = 5;
            }
            else if (event.keyCode == Keyboard.UP)
            {
                vy = -5;
            }
            else if (event.keyCode == Keyboard.DOWN)
            {
                vy = 5;
            }
        }
        function onKeyUp(event:KeyboardEvent):void
        {
            if (event.keyCode == Keyboard.LEFT || event.keyCode == Keyboard.RIGHT)
            {
                vx = 0;
            }
            else if (event.keyCode == Keyboard.DOWN || event.keyCode == Keyboard.UP)
            {
                vy = 0;
            }
        }
        function onEnterFrame(event:Event):void
        {
            //Move the player
            player.x += vx;
            player.y += vy;

            //determine top boundary
            if (! stage.hitTestPoint(player.x, (player.y-(player.height/2)), true ) ){
                player.y -= vy;
            }
        }
    }
}

score 2 · Accepted Answer · answered Dec 15 '11 at 07:53

Using the stage object with the shape flag set to true is will produce errors: You test, if any of the actual pixels rendered on the stage hits the point (which will probably return false, unless you have objects outside of the visible stage area, at exactly the point specified).

You can, of course, set that to false and try again (which would work better, but still leave the problem that you are testing against the bounding box around everything that is rendered on stage, rather than the actual stage area), but might I suggest a different approach?

It is more efficient, especially because your sprite is probably far smaller than the stage, to test the player's bounding box against the stage boundaries:

function onEnterFrame (ev:Event) : void {
    player.x += vx;
    player.y += vy;

    var playerBounds:Rectangle = player.getBounds(stage);
    if (playerBounds.left < 0 || playerBounds.right > stage.stageWidth) player.x -= vx;
    if (playerBounds.top < 0 || playerBounds.bottom > stage.stageHeight) player.y -= vy;
}

The player has to be located inside the visible stage area at startup, of course, and you might have to set focus to the stage to make sure keyboard events are captured.

I've use other methods successfully but I'm curious as to how `hitTestPoint` works. I've set the third parameter of `hitTestPoint` to false. The player object can now move north but instead of being stopped at the edge of the stage, it is stopped by an invisible barrier that has the same height as the player object. In the second parameter of `hitTestPoint`, I divided `player.height` by 4 instead but the player object will go off the stage bounds when it travels north. — user701510, Dec 15 '11 at 08:26
Like I said : hitTestPoint literally tests if a displayObject intersects with a point relative to the stage coordinates. The third parameter specifies if it is tested against the bounding box (i.e. a rectangle around everything that belongs to the object) or actual pixels. You can place a rectangle on the stage that is exactly the size of the visible area - then your hitTest might work for a while. But since you are placing and moving your player on the stage, moving it outside of the visible area will also change the bounding box! It is always best not to use hitTest on the stage object. — weltraumpirat, Dec 15 '11 at 08:35

using hitTestPoint() with stage object to create object boundaries

1 Answers1