13

I have more or less the following setting. In ~/path/to/my/packages I have two packages package1.m and package2.m. Each package's outline is, for example, the following:

BeginPackage["package1`"]
Unprotect@@Names["package1`*"];
ClearAll@@Names["package1`*"];

Begin["`Private`"]

vecNorm[vec_?VectorQ]:=Module[{},Return[Sqrt[vec.vec]]];

End[]
Protect@@Names["package1`*"];
EndPackage[]

Now, my problem is that I want to use vecNorm defined in package1.m in package2.m. How can I load (safely) package1 from within package2?

At the moment, I load manually both packages as follows:

SetDirectory[StringJoin[NotebookDirectory[], "packages"]];
Needs["package1`"]
Needs["package2`"]

from a notebook saved in ~/path/to/my. I want to load manually only package2 which in turn will load automatically and safely package1. In general I want a solution which changes as little as possible paths etc. of mathematica. What should be the best practice to accomplish this?

PS: By safely I mean that in the future, when I'll define package3 which will be using vecNorm as well and will be loading package1 as well no conflicts will happen.

Dror
  • 12,174
  • 21
  • 90
  • 160

1 Answers1

15

There are two generally recommended ways to load a package. One is so-called public import, and in your setting it will be done as

BeginPackage["package2`",{"package1`"}]

(* Usage messages etc *) 

Begin["`Private`"]

(* code here *)

End[]
EndPackage[]

Here, you indicate the context name of the package you want to load, in the list which is a second optional argument to BeginPackage. This way of importing is called public because the loaded package will remain on the $ContextPath after your main package is loaded, and will thus be publicly available.

The second method is called private import, and is schematically done as

BeginPackage["package2`"]

(* Usage messages etc *) 

Begin["`Private`"]
Needs["package1`"]

(* code here *)

End[]
EndPackage[]

In this method, your loaded second package will only be available to the package that loads it (with Needs), thus private import.

Which way you need will depend on the situation. I try to make all my imports private unless I have to make them public. For debugging, however, it may be handy to first make a public import, since then you can play with the second package directly at the top-level.

As for the safety, you can load a package by any number of packages, and this will be safe. When you load several packages into the same context simultaneously, this will be safe as long as those packages don't have public symbols with the same short name. Otherwise, you will run into what is called a shadowing problem, but it is best to make the effort needed to avoid that (it is always possible).

Leonid Shifrin
  • 22,449
  • 4
  • 68
  • 100
  • Your first method solved my problem! Thanks. As for the second one, when trying it out, it seems like there's a problem with the search path and `package1` doesn't manage to find `package2`. - I tried this option by myself as well and it didn't work. – Dror Dec 05 '11 at 12:47
  • 2
    @Dror The second method should work fine. If it doesn't, this should mean that you placed your second package somewhere where Mathematica can not find it. You should then either relocate your packages to a place where M can find them (e.g. `$UserBaseDirectory`), or add the directory containing your packages to the `$Path` variable. Actually, either both import methods work, or both should fail, so I am a bit puzzled by your situation. – Leonid Shifrin Dec 05 '11 at 12:51
  • I want a solution which is as free from paths changes as possible, since all this is in a shared directory and I don't know what are the settings of my collaborators. Indeed, it seems like the second method doesn't find the base-package. I'm for sure puzzled; but happy that there is a solution :) – Dror Dec 05 '11 at 13:06
  • 1
    @Dror Both methods are equivalent in their (in)dependence of the paths. Both of them are loading packages with their context names (which is a recommended practice), and should work as long as you place your packages where M can find them. As I said, I find the situation you described quite puzzling - if the second method fails, the first should also fail. – Leonid Shifrin Dec 05 '11 at 13:09
  • I understand that but it doesn't. I would be happy to investigate it together further, and understand the what/why/etc. here. – Dror Dec 05 '11 at 13:11
  • 1
    @Dror If you really want to dig deeper, I recommend asking a separate question about it, giving the exact code of both packages, and the exact setup you have to load them (which directory they are in, which commands you use to load them, what are the error messages, etc). Then, I or other folks here will be in a better position to help. – Leonid Shifrin Dec 05 '11 at 13:18
  • The second method doesn't seem to work for me either. Could it be that because `SetDelayed`/`Module` definitions are `HoldAll`, when the function is actually invoked any private import package is not available, since it will run in the `Global` context? – Meh Oct 12 '13 at 02:33
  • @Leonid I figured this out - the problem is with a type loaded with `LoadNETType`, which is not visible when a private import of `NETLink` is used, even if you use the fully qualifying name of that type. – Meh Oct 12 '13 at 13:23
  • @Adal Good to know. Consider asking your questions on the dedicated Mathematica site: http://mathematica.stackexchange.com/. This one is history now, more or less. – Leonid Shifrin Oct 12 '13 at 15:13