Compojure regex for matching a trailing slash

Question

Maybe I'm just an idiot, but I can't set up a match for an optional trailing slash in Clojure.

lein repl
REPL started; server listening on localhost port 47383
user=> (use 'ring.mock.request 'clout.core)
nil
user=> (route-matches "/article/" (request :get "/article/"))
{}
user=> (route-matches "/article/?" (request :get "/article"))
nil
user=> (route-matches "/article/?" (request :get "/article/"))
nil
user=> (route-matches #"/article/?" (request :get "/article/"))
java.lang.IllegalArgumentException: No implementation of method: :route-matches of protocol: #'clout.core/Route found for class: java.util.regex.Pattern (NO_SOURCE_FILE:0)

What regex can I use to match an optional trailing slash in Compojure?

score 5 · Accepted Answer · answered Dec 05 '11 at 05:55

The path string expected by clout as the first argument to route-matches is not a regex, but a string that can contain keywords and the * wildcard.

I believe clout doesn't natively support defining routes that ignore a trailing slash. You could solve the problem with a middleware function that removes trailing slashes. The following functions were taken from an old version of the compojure source code (before the big refactoring), I couldn't find out if they moved to a new place. Here is the original commit that introduced these functions.

(defn with-uri-rewrite
  "Rewrites a request uri with the result of calling f with the
   request's original uri.  If f returns nil the handler is not called."
  [handler f]
  (fn [request]
    (let [uri (:uri request)
          rewrite (f uri)]
      (if rewrite
        (handler (assoc request :uri rewrite))
        nil))))

(defn- uri-snip-slash
  "Removes a trailing slash from all uris except \"/\"."
  [uri]
  (if (and (not (= "/" uri))
           (.endsWith uri "/"))
    (chop uri)
    uri))

(defn ignore-trailing-slash
  "Makes routes match regardless of whether or not a uri ends in a slash."
  [handler]
  (with-uri-rewrite handler uri-snip-slash))

Ah, I was hoping to avoid middleware. If it's the only way though, then OK. — Kevin Burke, Dec 05 '11 at 06:44

Brad Koch · Answer 2 · 2014-04-21T14:18:05.153

1

Here's a condensed version of the middleware with no dependencies:

(defn with-ignore-trailing-slash [handler] (fn [request]
  (let [uri       (request :uri)
        clean-uri (if (and (not= "/" uri) (.endsWith uri "/"))
                    (subs uri 0 (- (count uri) 1))
                    uri)]
    (handler (assoc request :uri clean-uri)))))

Bug fix edits welcome.

edited Apr 21 '14 at 14:18

answered Mar 20 '14 at 01:18

Brad Koch

19,267
19
110
137

artgon · Answer 3 · 2016-03-10T19:55:36.750

0

For those looking for an even more compressed solution :)

(defn- with-ignore-trailing-slash [handler]
  (fn [request]
    (let [uri (request :uri)
          clean-uri (str/replace uri #"^(.+?)/+$" "$1")]
      (handler (assoc request :uri clean-uri)))))

edited Mar 10 '16 at 19:55

answered Mar 10 '16 at 18:53

artgon

714
1
6
9

Compojure regex for matching a trailing slash

3 Answers3