1

what i want to do is a typical grouping that can usualy be done using xsl:key, but it become more complicated as data to groups are in 2 differents files. How process ? Here is an example of what i want to do, can i request your help ? must be xslt-1.0 compliant.

bookreference.xml : 

<t>  
    <book isbn="1">  
        <category>SF</category>  
    </book>  
    <book isbn="2">  
        <category>SF</category>  
    </book>  
    <book isbn="3">  
        <category>SF</category>  
    </book>  
    <book isbn="4">  
        <category>Comedy</category>  
    </book>  
    <book isbn="5">  
        <category>Comedy</category>  
    </book>
</t>

mylibrary.xml :

<t>  
   <book isbn="1">
       <price>10</price>
   </book>
   <book isbn="2">
      <price>10</price>
   </book>       
   <book isbn="3">
      <price>20</price>
   </book>
   <book isbn="4">
      <price>5</price>
   </book>
</t>

output wanted: 

SF : 3 book(s) - Total : 40$
Comedy : 2 book(s) - Total : 5$
Seb
  • 141
  • 2
  • 7
  • Well one possible XSLT 1.0 process is to first merge the two documents into a result tree fragment, then to use an extension function like exsl:node-set to convert the result tree fragment into a node-set, then you can use Muenchian grouping as usual on that node-set. So which XSLT 1.0 processor do you target, does it have exsl:node-set or similar? – Martin Honnen Nov 30 '11 at 11:46
  • Hi Martin, xsltproc as XSLT 1.0 processor. So it must be ok, i will give a try to your approach. – Seb Nov 30 '11 at 12:04
  • Why are you providing malformed XML? There are at least two problems with each of the two fragments provided. Please, edit and correct. – Dimitre Novatchev Nov 30 '11 at 13:26
  • @_Dimitre : All my apologizes for the malform XML : Fix Done. – Seb Nov 30 '11 at 14:47

2 Answers2

0

As already suggested in my comment, you can first merge two documents into a result tree fragment, then use exsl:node-set to get a node-set on which you can then apply Muenchian grouping:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common"
  exclude-result-prefixes="exsl"
  version="1.0">

  <xsl:param name="price-url" select="'test2011113002.xml'"/>
  <xsl:variable name="doc2" select="document($price-url)"/>

  <xsl:output method="text"/>

  <xsl:variable name="rtf">
    <xsl:apply-templates select="//book" mode="merge"/>
  </xsl:variable>

  <xsl:template match="book" mode="merge">
    <xsl:copy>
      <xsl:variable name="isbn" select="@isbn"/>
      <xsl:copy-of select="@* | node()"/>
      <xsl:for-each select="$doc2">
        <xsl:copy-of select="key('k1', $isbn)/price"/>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

  <xsl:key name="k1" match="book" use="@isbn"/>
  <xsl:key name="k2" match="book" use="category"/>

  <xsl:template match="/">
    <xsl:apply-templates select="exsl:node-set($rtf)/book[generate-id() = generate-id(key('k2', category)[1])]"/>
  </xsl:template>

  <xsl:template match="book">
    <xsl:variable name="current-group" select="key('k2', category)"/>
    <xsl:value-of select="concat($current-group/category, ': ', count($current-group), ' - Total : ', sum($current-group/price), '&#10;')"/>
  </xsl:template>

</xsl:stylesheet>
Martin Honnen
  • 160,499
  • 6
  • 90
  • 110
0

Good question, +1.

There is no need for complicated (more than necessary) grouping or for any extension functions:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kBookByCat" match="book"
      use="category"/>

 <xsl:key name="kPriceByIsbn" match="price"
      use="../@isbn"/>

 <xsl:variable name="vMyLib" select=
 "document('file:///c:/temp/delete/mylibrary.xml')"/>

 <xsl:template match=
  "book[generate-id()
       =
        generate-id(key('kBookByCat', category)[1])
        ]
  ">
     <xsl:variable name="vBooksinCat" select=
          "key('kBookByCat', category)"/>

     <xsl:value-of select="category"/> : <xsl:text/>
     <xsl:value-of select="count($vBooksinCat)"/>
     <xsl:text> book(s) - Total : $</xsl:text>

     <xsl:for-each select="$vMyLib">
      <xsl:value-of select="sum(key('kPriceByIsbn', $vBooksinCat/@isbn))"/>
      <xsl:text>&#xA;</xsl:text>
     </xsl:for-each>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

When this transformation is applied on the first of the two provided data fragments (corrected to well-formed XML document):

<t>
    <book isbn="1">
        <category>SF</category>
    </book>
    <book isbn="2">
        <category>SF</category>
    </book>
    <book isbn="3">
        <category>SF</category>
    </book>
    <book isbn="4">
        <category>Comedy</category>
    </book>
    <book isbn="5">
        <category>Comedy</category>
    </book>
</t>

and having the second data fragment (corrected to well-formed XML document) saved as C:\Temp\Delete\mylibrary.xml,

The wanted, correct result is produced:

SF : 3 book(s) - Total : $40
Comedy : 2 book(s) - Total : $5
Dimitre Novatchev
  • 240,661
  • 26
  • 293
  • 431
  • @_Dimitre :thanks for your solution and to advise me on malform xml. – Seb Nov 30 '11 at 14:48
  • @_Dimitre : after studying your code, in fact it does not match the requirements because i think i was not clear to explain my needs. I want to get as output the number and total Price of books in my Library group by family and Not the full pricing and number of book in References group by family. I modify example to be more explicit. – Seb Nov 30 '11 at 15:13
  • @Seb: My answer produces exactly the wanted results as provided in your question -- before you changed it 10 minutes ago! If you have a new question -- *ask* a new question. Your question was fully answered. Also, there is no mention of "family" in the text of your question, so your comment is contradicting it. What is "family"? Please, stop modifying this question, accept the best answer ans ask new questions. BTW, I think that the solution in my answer still produces the correct result even for the modified question. – Dimitre Novatchev Nov 30 '11 at 15:33
  • @_Dimitre : family = category. Before and after edition, my output was still same for the COMEDY category => Comedy : 1 book(s) - Total : 5$ because only 1 comedy book in my library. – Seb Nov 30 '11 at 15:46
  • i modify the output in question to match result of both, i accept the answer, as it is usefull (not seen on any other forum) and will open a new question explaining more carrefully my need. – Seb Nov 30 '11 at 16:22
  • @Seb: I am at work and will have time to look at your modified question in 6 hours' time. As for "accept the answer", you have already accepted another answer, that is unnesecarily complicated and requires the use of a vendor-specific extension function. – Dimitre Novatchev Nov 30 '11 at 20:30
  • @_Dimitre: sorry, work of stackoverflow is new for me, we can accept only one response ? I got a xsl that may work giving the output i need (not yet validate), but i am sure you may help optimising it. See you on the rewrite question thread. – Seb Nov 30 '11 at 22:31