From Coordinate to Degree

Question

How could I get the angle in Degree from 0 to 360 from Cartesian coordinate such that :

{1,0}  = 0   Degree
{0,1}  = 90  Degrees
{-1,0} = 180 Degrees
{0,-1} = 270 Degrees

I am having a hard Time with ArcTan to get the angle bet 180 to 359...

Dr. belisarius · Accepted Answer · 2011-11-19T23:34:24.103

3

Try:

f[x_List] := Mod[ArcTan @@ x /Pi 180 Degree, 360 Degree]

f /@ {{0, -1}, {0, 1}, {1, 0}, {-1, 0}}
(*
 -> {270 \[Degree], 90 \[Degree], 0, 180 \[Degree]}
*)

Edit

As the previous form was criticized upon, here is another way to do the same. Not so easy to follow for my taste:

f = (180 /Pi ArcTan @@ #)~Mod~360 &

edited Nov 19 '11 at 23:34

answered Nov 19 '11 at 21:48

Dr. belisarius

60,527
15
115
190

Why do you use `f[#]&` instead of `f`? – Szabolcs Nov 19 '11 at 22:01
@Sza As usual, I was trying several alternatives and forgot to clean up the code :) – Dr. belisarius Nov 19 '11 at 22:05
Why do you use `ArcTan[Sequence @@ x]` instead of `ArcTan @@ x`? – Sjoerd C. de Vries Nov 19 '11 at 22:21
@Sjoerd Because I think it is easier to follow for the OP – Dr. belisarius Nov 19 '11 at 22:22
1

I'd say you're making it more complicated. How on earth can the first form seen as simpler than the second? – Sjoerd C. de Vries Nov 19 '11 at 22:26
@Sjoerd because I saw previously that many newcomers don't realize that `@@` removes `List[]`. But it may be a prejudice. – Dr. belisarius Nov 19 '11 at 22:34
I feel that `Sequence`+`Apply` is much more exotic than `Apply` on its own. `Sequence` is a function learners of MMA will encounter rather late if ever. – Sjoerd C. de Vries Nov 19 '11 at 23:30
@acl Yoda posted the same comment and then deleted it. The upvote from Mr. was the only reason to do the archeological job of searching for the `~` at my non conventional keyboard :D – Dr. belisarius Nov 19 '11 at 23:37
@acl Still worse `f = (ArcTan @@ #/Pi)~Mod~2 180 &` – Dr. belisarius Nov 20 '11 at 00:00
@belisarius ouch. on the other hand, the previous construction had 5 symbols one after the other, namely, `@@#)~`, while this has only `@@ #/`, a mere 4... – acl Nov 20 '11 at 00:03
@belisarius yes i felt a definite sense of relief when I saw in the comments that i'm not the only one overwhelmed by Mr.W's notational heroics – acl Nov 20 '11 at 00:19

Arnoud Buzing · Answer 2 · 2011-11-20T02:12:24.810

Try this:

CoordinateToDegree[x_?NumberQ, y_?NumberQ] := 
 Rescale[ArcTan[-x, y], {-Pi, Pi}, {360, 0}]

Using ArcTan[-x,y] you will be aligning on the branch cut so you get a continuous function for the angle. Then Rescale maps the range -Pi...Pi to 0...360.

Here is simple Manipulate which demonstrates this solution:

Manipulate[
 Graphics[{
  Orange, Disk[],
  Black, Text[Style[CoordinateToDegree[Cos[t], Sin[t]], "Title"], {Cos[t], Sin[t]}]},
 PlotRange -> 1.4], {t, 0, 2 \[Pi]}]

enter image description here

score 2 · Answer 3 · answered Nov 19 '11 at 21:51

2

I think this works, despite being ugly:

todeg[x_, y_] := If[# < 0, 360 + #, #] &@(N@ArcTan[x, y]/Degree)

answered Nov 19 '11 at 21:51

acl

6,490
1
27
33

From Coordinate to Degree

3 Answers3