How to pad out character fields in SAS?

Question

I am creating a SAS dataset from a database that includes a VARCHAR(5) key field.

This field includes some entries that use all 5 characters and some that use fewer.

When I import this data, I would prefer to pad all the shorter entries out to use all five characters. For this example, I want to pad on the left with 0, the character zero. So, 114 would become 00114, ABCD would become 0ABCD, and EA222 would stay as it is.

I've attempted this with a simple data statement, but of course the following does not work:

data test;
    set databaseinput;
    format key $5.;
run;

I've tried to do this with a user-defined informat, but I don't think it's possible to specify the ranges correctly on character fields, per this SAS KB answer. Plus, I'm fairly sure proc format won't let me define the result dynamically in terms of the incoming variable.

I'm sure there's an obvious solution here, but I'm just missing it.

Yes, `00ABC` is correct in my case. Also, nice point about the use of code tags. Original post updated. — purple_arrows, Nov 07 '11 at 18:13
Can the entries contain spaces? For example `AB_C` or even `_AB_` (where the underscore represents a space)? — Robert Penridge, Nov 08 '11 at 18:06

score 6 · Accepted Answer · answered Feb 21 '12 at 15:25

6

Here is an alternative:

data padded_data_dsn; length key $5;
    drop raw_data;
    set raw_data_dsn(rename=(key=raw_data));
    key = translate(right(raw_data),'0',' ');
run;

answered Feb 21 '12 at 15:25

ChrisP

5,812
1
33
36

score 5 · Answer 2 · answered Jan 09 '13 at 21:18

5

Data raw_data_dsn;
format key $5.;
key = '4'; key1 = CATT(REPEAT('0',5-length(key)),key);output;
key = 'A114'; key1 = CATT(REPEAT('0',5-length(key)),key);output;
key = 'A1140'; key1 = CATT(REPEAT('0',5-length(key)),key);output;
run;

answered Jan 09 '13 at 21:18

Venkateshwaran

51
1
1

score 2 · Answer 3 · answered Nov 07 '11 at 22:54

I'm sure someone will have a more elegant solution, but the following code works. Essentially it is padding the variable with five leading zeros, then reversing the order of this text string so that the zeros are to the right, then reversing this text string again and limiting the size to five characters, in the original order but left-padded with zeros.

data raw_data_dsn;
   format key $varying5.;
   key = '114'; output;
   key = 'ABCD'; output;
   key = 'EA222'; output;
run;

data padded_data_dsn;
   format key $5.;
   drop raw_data;
   set raw_data_dsn(rename=(key=raw_data));
   key = put(put('00000' || raw_data ,$revers10.),$revers5.);
run;

Took me forever to get around to validating this answer, but it's spot on for my problem. — purple_arrows, Dec 21 '11 at 19:55

dwjohnston · Answer 4 · 2014-08-26T03:14:22.750

Here's what worked for me.

data b (keep = str2);
    format str2 $5. ;
    set a;
    catlength = 4 - length(str); 
    cat = repeat('0', catlength);
    str2 = catt(cat, str); 
run;

It works by counting the length of the existing string, and then creating a cat string of length 4 - that, and then appending the cat value and the original string together.

Notice that it screws up if the original string is length 5. Also - it won't work if the input string has a $5. format on it.

data a; /*input dataset*/
    input str $;
    datalines;
    a
    aa
    aaa
    aaaa
    aaaaa
    ;
run;

data b (keep = str2);
    format str2 $5. ;
    set a;
    catlength = 4 - length(str); 
    cat = repeat('0', catlength);
    str2 = catt(cat, str); 
run;

input:
a
aa
aaa
aaaa
aaaaa

output:
0000a   
000aa   
00aaa   
0aaaa   
0aaaa

score 0 · Answer 5 · answered Sep 10 '14 at 14:25

0

I use this, but only works with numeric values :S. Try with another formats in the INPUT

data work.prueba;
    format xx $5.;
    xx='1234';
    vv=PUT(INPUT(xx,best5.),z5.);
run;

answered Sep 10 '14 at 14:25

Diego

1

How to pad out character fields in SAS?

5 Answers5