How can I output unique, count and sum using perl

Question

I am new to Perl. I need to find the unique, count and sum for the following data. I request your help.

08/2009   I-111   300
08/2009   I-112   400
08/2009   I-113   500
10/2009   I-200   1000
10/2009   I-300   500
11/2009   I-300   100
11/2009   I-100   400

So I need to find like this

08/2009 3 1200
10/2009 2 1500

Answer 1

uniq from List::MoreUtils returns the unique elements of a list:

use List::MoreUtils 'uniq';
my @x = uniq 1, 1, 2, 2, 3, 5, 3, 4;    # (1,2,3,5,4)

A list expression in scalar context returns the number of elements.

my @array = (5,6,7,8);
my $a_count = @array;       # 4

my %hash = ('x' => 1, 'y' => 2);
my $h_count = keys %hash;   # 2

sum from List::Util adds the elements of a list.

use List::Util 'sum';
my @array = (1,2,3,4,5);
print sum @array;   # 15

Answer 2

Not sure what you want exactly, but is this ok?

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dump qw(dump);

my %h;
while(<DATA>) {
    chomp;
    my @el = split;
    $h{$el[0]}{count}++;
    $h{$el[0]}{sum} += $el[2];
}
dump%h;

__DATA__
08/2009   I-111   300
08/2009   I-112   400
08/2009   I-113   500
10/2009   I-200   1000
10/2009   I-300   500
11/2009   I-300   100
11/2009   I-100   400

output:

(
  "08/2009",
  { count => 3, sum => 1200 },
  "11/2009",
  { count => 2, sum => 500 },
  "10/2009",
  { count => 2, sum => 1500 },
)

Answer 3

Re: M42's answer, try:

use Data::Dumper;
print Dumper \%h;

Or you could just write:

while (my ($key, $values) = each %h) {
    print "$key $values->{count} $values->{sum}\n";
}

Answer 4

Normally, I don't do Write my program for free type stuff, but since M42 already did most of it, here's it is without the Data::Dump:

#!/usr/bin/perl
use strict;
use warnings;

my %h;
while(<DATA>) {
    chomp;
    my @el = split;
    $h{$el[0]}->{count}++;
    $h{$el[0]}->{sum} += $el[2];
}

foreach my $element (sort keys %h) {
    printf "%-10.10s  %-6.6s  %4d\n", $element, 
    $h{$element}->{count}, $h{$element}->{sum};
}
__DATA__
08/2009   I-111   300
08/2009   I-112   400
08/2009   I-113   500
10/2009   I-200   1000
10/2009   I-300   500
11/2009   I-300   100
11/2009   I-100   400   

Now learn yourself some Perl!