0

I am trying to loop over a different set of control variables. I run the below code but get an error { required. Any help would be appreciated.

local tmax "tmax_3 tmax_2 tmax_1 tmax0 tmax1 tmax2 tmax3"
local tmin "tmin_3 tmin_2 tmin_1 tmin0 tmin1 tmin2 tmin3"
local precip "precip_3 precip_2 precip_1 precip0 precip1 precip2 precip3"

est clear
local m=1
foreach var of varlist good_health better_health {
    foreach weather of local tmax tmin precip {
        eststo model_`m'_`weather': reg `var' `weather', robust cluster(parish_id)
        local m `++m'
    }
}
Alonso Quijano
  • 73
  • 6

1 Answers1

2

When using syntax of local in foreach Stata expects only one local. So after the first local Stata expects a {. But you have a second and a third local before the {. You should be able to solve this using in in foreach where Stata first interprets your three locals, then iterate over all items in each of them. See below.

local tmax "tmax_3 tmax_2 tmax_1 tmax0 tmax1 tmax2 tmax3"
local tmin "tmin_3 tmin_2 tmin_1 tmin0 tmin1 tmin2 tmin3"
local precip "precip_3 precip_2 precip_1 precip0 precip1 precip2 precip3"

est clear
local m=1
foreach var of varlist good_health better_health {
    foreach weather in tmax tmin precip {
        eststo model_`m'_`weather': reg `var' ``weather'', robust cluster(parish_id)
        local m `++m'
    }
}

Edit: Now you are only iterating over the names of the local. ``weather'' is now a nested local, where it first gets the name that the local `weather' points to, then it interprets that local and gets your variable list.

TheIceBear
  • 2,912
  • 9
  • 23
  • Thanks for the solution. The code run but it does not show the desired output. It loops over each of the variables within each local. Instead I would like it to loop over the three locas as one set. I would likesix regressions (2 independent variables x3 sets of controls), instead of 2 x 3 x 6. In other words, these are the six regression: `reg good_health $tmax`, `reg good_health $tmin`, `reg good_health $precip`, `reg better_health $tmax`, `reg better_health $tmin`, `reg better_health $precip` – Alonso Quijano Jul 16 '23 at 20:18
  • Perhaps, I should have used global macros instead of locals. – Alonso Quijano Jul 16 '23 at 21:08
  • I have made an edit to my answer – TheIceBear Jul 16 '23 at 21:59
  • It worked, thanks! – Alonso Quijano Jul 16 '23 at 23:09