Recently, I'm trying to use threads::shared to share some data between threads, and I was confused by the usage of $var = &share([]); in perldoc, what's the effect of the & before share?
Asked
Active
Viewed 60 times
1 Answers
6
& tells Perl to ignore the prototype.
share is documented to accept a scalar, an array or a hash.
share( $scalar_to_share )
share( @array_to_share )
share( %hash_to_share )
But it's impossible to pass arrays and hashes to subs. So what's going on?
share has a prototype (\[$@%]) which changes how the call is made. Rather than evaluating the argument list as usual, a reference to the provided variable is passed instead.
share( $scalar_to_share ) # Equivalent to `&share( \$scalar_to_share )`
share( @array_to_share ) # Equivalent to `&share( \@array_to_share )`
share( %hash_to_share ) # Equivalent to `&share( \%hash_to_share )`
What if you want to provide a reference to an anonymous array? You can't just pass a reference, since that would share the scalar.
my $ref = [];
share( $ref ); # XXX Would share `$ref` instead of the array.
As documented, you can simply bypass the prototype.
my $ref = [];
&share( $ref ); # ok
Conveniently, share returns its argument.
my $ref = &share( [] ); # ok
You could also provide the array required by the prototype by dereferencing the reference.
my $ref = share( @{ [] } ); # ok
my $ref = share( []->@* ); # ok
ikegami
- 367,544
- 15
- 269
- 518
-
Thanks a lot, what's the name of the syntax in last two lines, the syntax of perl is so flexible :sigh. – rodman10 Jun 21 '23 at 03:23
-
1`@BLOCK` and `EXPR->@*` are [array dereferences](https://stackoverflow.com/q/46507722/589924). – ikegami Jun 21 '23 at 13:15
-
Thanks ! The matrix is very helpful for understanding deference syntax. – rodman10 Jun 21 '23 at 14:07