SAS: Generate separate plots for a list of variables in a single SGPLOT statement (such as can be done with PROC UNIVARIATE or PROC CHART)

Question

A dataset has 10 variables ('a' through 'f'), half quantitative and half categorical, and you want to generate a separate visual representation of each of these variables (histograms for the quantitative and bars for the categorical) with the minimum number of statements.

PROC UNIVARIATE can be used with quantitative variables and accepts multiple variables in the HISTOGRAM statement:

WORKING EXAMPLE: PROC UNIVARIATE takes multiple variables in the HISTOGRAM statement

proc univariate data=DATA noprint;
histogram a b c d e;
run;

which outputs five separate histograms, one for each variable. But PROC UNIVARIATE cannot output bar charts for the categorical variables, and PROC FREQ only has statements which output tables.

PROC SGPLOT has both the HISTOGRAM and HBAR/VBAR statements, but does not accept multiple variable arguments in the manner that PROC UNIVARIATE does.

INVALID EXAMPLE: SGPLOT does not accept multiple variables in the HISTOGRAM or HBAR/VBAR statements.

proc sgplot data=DATA;
vbar f g h i j;
run;

throws the following errors at the character between 'f' and 'g': ERROR 22-322: Syntax error, expecting one of the following: ;, /.
ERROR 202-322: The option or parameter is not recognized and will be ignored.

Is the only solution to write a separate SGPLOT statement for each categorical variable as below?

WORKING EXAMPLES: Single variable per statement

proc sgplot data=DATA;
vbar f;
run;

successfully generates a VBAR for 'f', and

proc sgplot data=DATA;
vbar g;
run;

successfully generates a VBAR for 'g'.

For a dataset with few variables this may not be difficult, but what about for large datasets?

If you're using Studio or EG, look at the Characterize data task. It's also pretty common in any language to build your own exploratory macro that will create the summary stats for the desired data. — Reeza, May 08 '23 at 15:30
Also, PROC FREQ does generate various plots not just tables, the PLOT option is on the TABLES statement. https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/procstat/procstat_freq_syntax08.htm#procstat.freq.freqplots — Reeza, May 08 '23 at 15:37

score 2 · Answer 1 · answered May 06 '23 at 18:33

One option is to use the macro language to generate a bunch of SGPLOT steps. So you write a macro that you call like

%barchart(data=mydata,var=a b c)

Another solution is to transpose your data into a vertical format. So instead of data like:

ID  A  B  C
1   10 11 12
2   20 21 22

transpose it to:

ID Var Value
1  A   10
1  A   11
1  A   12
2  B   20
2  B   21
2  B   22

This would allow you do use a BY statement in SGPLOT to make multiple plots, e.g.

proc sort data=have;
  by var;
run;

pros sgplot data=have;
  vbar value;
  by var;
run;

score 0 · Answer 2 · answered May 08 '23 at 17:25

A simple macro for just the graphs, if other output is desired, the ODS statement can be modified.


%macro summary_data(dsn=,
                    cat= /*categorical variables separated by spaces, variable shortcuts are fine*/,
                    cont = /*continuous variables separated by spaces, variable shortcuts are fine*/);
                    
ods select freqplot;                    
proc freq data=&dsn.;
table &cat / plots=freqplot;
run;

ods select histogram;
proc univariate data=&dsn.;
var &cont.;
histogram &cont.;
run;

%mend;

Then execute the macro for demo.

%summary_data(dsn=sashelp.class, cat = age sex, cont=age weight height);

SAS: Generate separate plots for a list of variables in a single SGPLOT statement (such as can be done with PROC UNIVARIATE or PROC CHART)

2 Answers2