Get data from terraform Output and use it as input

Question

I'm using Terraform to build and automate infrastructure and I'm having trouble in finding the solution to grab the output of an Azure WebApp, specifically the Public IP addresses used by that WebApp and use them as inputs to update a Cloudflare list.

output "webapp_ip" {
  value = azurerm_linux_web_app.lwa.outbound_ip_addresses
}

will output something like this:

webapp_ip = "ip-address-1,ip-address-2,ip-address-3,ip-address-4"

and Cloudflare_list terraform resource receives data on the following format:

item {
    value {
      ip = "ip-address-1"
    }
    comment = "IP 1"}

item {
    value {
      ip = "ip-address-2"
    }
    comment = "IP 2"
}

I was thinking in dynamic lists but I don't know if it's the right way to go...

Yes you would probably need to convert from comma-delimited string to set in the output, and then use a dynamic block. — Matthew Schuchard, Mar 03 '23 at 16:42
You can use the split function, and then a dynamic block as you mention. — javierlga, Mar 03 '23 at 16:42
@MarkoE, the ouput is: webapp_ip = "ip-address-1,ip-address-2,ip-address-3,ip-address-4" — Pedro Et Ferreira, Mar 03 '23 at 17:21

score 1 · Accepted Answer · answered Mar 03 '23 at 18:11

1

Dynamic blocks is the right way to go here. Your code should look something like this:

resource "cloudflare_list" "example" {

  // some other attributes

  dynamic "item" {
    for_each = toset(split(",", azurerm_linux_web_app.lwa.outbound_ip_addresses)) // notice split
    content {
      value {
        ip = item.value
      }
      comment = "IP: ${item.value}"
    }
  }
}

If Azure and Cloudflare are in two different workspaces (states) you can use either terraform_remote_state or tfe_outputs to pass Azure outputs to Cloudflare.

answered Mar 03 '23 at 18:11

Anton

1,793
10
20

Thank you very much @Anton It did the trick! What I'm doing now is creating a _locals_ join to add more IP addresses to the final list: `join(",", [azurerm_linux_web_app.lwa.outbound_ip_addresses, "additional IP addresses"])` The final code is: `resource "cloudflare_list" "ethomelab_cloudflare" { dynamic "item" { for_each = toset(split(",", local.cloudflare_list_ips)) // notice split content { value { ip = item.value } comment = "IP: ${item.value}" } }` – Pedro Et Ferreira Mar 08 '23 at 10:02
@PedroEtFerreira glad it worked for you! Yes, moving complicated expressions to `locals` helps readability sometimes, I do that too. – Anton Mar 08 '23 at 11:30

Get data from terraform Output and use it as input

1 Answers1