Need help converting this indicator to version 5

Question

So I've been trying to convert this script into version 5 from version 1/2, and I can’t figure it out, I am not that experienced with old version under v4.

//@version=1
study(title = "SuperTrend ATR + RSI", shorttitle = "SuperTrend ATR + RSI", overlay = true)

//Mode
Factor=input(title="Super Trend", defval=3, minval=1,maxval = 100)
ATR=input(title="ATR", defval=7, minval=1,maxval = 100)
RSI = input(title="RSI", defval=7, minval=1, maxval = 100)

//Super Trend ATR
Up=hl2-(Factor\*atr(ATR))
Dn=hl2+(Factor\*atr(ATR))

TUp=close\[1\]\>TUp\[1\]? max(Up,TUp\[1\]) : Up
TDown=close\[1\]\<TDown\[1\]? min(Dn,TDown\[1\]) : Dn

Trend = close \> TDown\[1\] ? 1: close\< TUp\[1\]? -1: nz(Trend\[1\],1)
Tsl = Trend==1? TUp: TDown

linecolor = Trend == 1 ? green : red

//RSI
src = close,

ep = 2 \* RSI - 1
auc = ema( max( src - src\[1\], 0 ), ep )
adc = ema( max( src\[1\] - src, 0 ), ep )
x1 = (RSI - 1) \* ( adc \* 70 / (100-70) - auc)
ub = iff( x1 \>= 0, src + x1, src + x1 \* (100-70)/70 )
x2 = (RSI - 1) \* ( adc \* 30 / (100-30) - auc)
lb = iff( x2 \>= 0, src + x2, src + x2 \* (100-30)/30 )

//Affichage
plot(avg(ub, lb), color=purple, style = line, linewidth=1, title="RSI")
plot(Tsl, color = linecolor , style = line , linewidth = 1,title = "SuperTrend ATR")

I’ve tried to do everything within my knowledge to try to unlock this.

What have you tried? Where do you need help? Do you get some errors or what? — vitruvius, Nov 16 '22 at 07:45

score 0 · Answer 1 · answered Nov 16 '22 at 13:59

//@version=5
//Crée par J.Dow
//SuperTrend ATR, Le type ATR calcule la volatilité à partir de l'Average True Range (ATR), il est idéal pour le FOREX
// Le RSI et idéal pour voir la force d'un mouvement
indicator(title='SuperTrend ATR + RSI', shorttitle='SuperTrend ATR + RSI', overlay=true)

//Mode
Factor = input.int(title='Super Trend', defval=3, minval=1, maxval=100)
ATR = input.int(title='ATR', defval=7, minval=1, maxval=100)
RSI = input.int(title='RSI', defval=7, minval=1, maxval=100)

//Super Trend ATR
Up = hl2 - Factor * ta.atr(ATR)
Dn = hl2 + Factor * ta.atr(ATR)

TUp = 0.0
TDown = 0.0
TUp := close[1] > TUp[1] ? math.max(Up, TUp[1]) : Up
TDown := close[1] < TDown[1] ? math.min(Dn, TDown[1]) : Dn

Trend = 0.0
Trend := close > TDown[1] ? 1 : close < TUp[1] ? -1 : nz(Trend[1], 1)
Tsl = Trend == 1 ? TUp : TDown

linecolor = Trend == 1 ? color.green : color.red

//RSI
src = close

ep = 2 * RSI - 1
auc = ta.ema(math.max(src - src[1], 0), ep)
adc = ta.ema(math.max(src[1] - src, 0), ep)
x1 = (RSI - 1) * (adc * 70 / (100 - 70) - auc)
ub = x1 >= 0 ? src + x1 : src + x1 * (100 - 70) / 70
x2 = (RSI - 1) * (adc * 30 / (100 - 30) - auc)
lb = x2 >= 0 ? src + x2 : src + x2 * (100 - 30) / 30

//Affichage
plot(math.avg(ub, lb), color=color.new(color.purple, 0), style=plot.style_line, linewidth=1, title='RSI')
plot(Tsl, color=linecolor, style=plot.style_line, linewidth=1, title='SuperTrend ATR')

Need help converting this indicator to version 5

1 Answers1