How to distinguish different objects in the same struct using Symbol in Julia?

Question

As mentioned in the title, I want to use multiple-dispatch to assign different behaviors of the same struct, distinguished by Symbol. The struct can be constructed as follows:

struct AbstractAlgorithm
    algorithmName::String
    algorithmSymbol::Symbol

    function AbstractAlgorithm(algorithmName::String)
        if algorithmName ∉ ("Value Iteration", "Policy Iteration")
            error("Given algorithm $algorithmName not defined yet.")
        elseif algorithmName=="Value Iteration"
            new(algorithmName, Symbol("vIter"))
        elseif algorithmName=="Policy Iteration"
            new(algorithmName, Symbol("pIter"))
        end
    end  
end

And I wanted to distinguish the same struct using different symbols in a function, such as:

function A(a::AbstractAlgorithm with Symbol vIter) = do A1
function A(a::AbstractAlgorithm with Symbol pIter) = do A2

How should I design function A using multiple-dispatch?

DNF · Answer 1 · 2022-11-11T06:24:46.247

5

This seems like a highly unusual and un-idiomatic approach, since Julia natively supports multiple dispatch. Also, AbstractNN is a naming convention for abstract types, while you are using it for a concrete type.

Why not instead use dispatch:

abstract type AbstractAlgorithm end

struct ValueIteration <: AbstractAlgorithm end

struct PolicyIteration <: AbstractAlgorithm end

and then implement your wanted behaviors based on the types of your algorithm objects:

A(::ValueIteration) = A1() 
A(::PolicyIteration) = A2()

edited Nov 11 '22 at 06:24

answered Nov 11 '22 at 06:07

DNF

11,584
1
26
40

Thanks for your answer. These two algorithms share some members so I would like to use the same struct to describe them. – PokeLu Nov 11 '22 at 10:02
Why? Just repeat the shared structure. – StefanKarpinski Nov 11 '22 at 18:12

score 5 · Accepted Answer · answered Nov 11 '22 at 06:28

I am adding as an answer a small comment to what @Giovanni proposed since it is too long (+ some minor changes to your code).

If you want to use a parametric type (and not, as @DNF proposed a type hierarchy) you can just write:

struct Algorithm{T}
    algorithmName::String

    function Algorithm(algorithmName::AbstractString)
        algorithmName == "Value Iteration" && return new{:vIter}(algorithmName)
        algorithmName == "Policy Iteration" && return new{:pIter}(algorithmName)
        error("Given algorithm $algorithmName not defined yet.")
    end
end

function A(a::Algorithm{:pIter})
    # ...
end

function A(a::Algorithm{:vIter})
    # ...
end

The point is that Symbol can be used as type parameter, so you do not have to wrap it in Val.

score 3 · Answer 3 · answered Nov 11 '22 at 02:59

One solution could be using Val

struct AbstractAlgorithm{T}
    algorithmName::String

    function AbstractAlgorithm(algorithmName::String)
        if algorithmName ∉ ("Value Iteration", "Policy Iteration")
            error("Given algorithm $algorithmName not defined yet.")
        elseif algorithmName=="Value Iteration"
            new{Val{:vIter}}(algorithmName)
        elseif algorithmName=="Policy Iteration"
            new{Val{:pIter}}(algorithmName)
        end
    end
end

function A(a::AbstractAlgorithm{Val{:pIter}})
    A1
end

function A(a::AbstractAlgorithm{Val{:vIter}})
    A2
end

How to distinguish different objects in the same struct using Symbol in Julia?

3 Answers3