-2

Need someone who understands pine editor. My indicator has no version. can anyone make version 5?

I tried to make every version but I couldn't do it because I don't have any coding knowledge.

//www.askincantum.com
study(title = "instagram: askincantum", shorttitle = "instagram: askincantum", overlay = true)

//Mode
RSI = input(title="bab", defval=80, minval=1, maxval = 100)

//RSI
src = close,

ep = 2 * RSI - 1
auc = ema( max( src - src[1], 0 ), ep )
adc = ema( max( src[1] - src, 0 ), ep )
x1 = (RSI - 1) * ( adc * 70 / (100-70) - auc)
ub = iff( x1 >= 0, src + x1, src + x1 * (100-70)/70 )
x2 = (RSI - 1) * ( adc * 30 / (100-30) - auc)
lb = iff( x2 >= 0, src + x2, src + x2 * (100-30)/30 )

//Affichage
plot(avg(ub, lb), color=white , style = line, linewidth=2, title="Line")


len = input(20, minval=1, title="Entry")
src1 = input(close, title="Source")
offset = input(title="Offset", type=integer, defval=0, minval=-500, maxval=500)
out = wma(src1, len)
plot(out, title="Entry", color=yellow, linewidth = 2, offset=offset)

buy = crossover(out , avg(ub, lb))
sell = crossunder(out, avg(ub, lb))


plotshape(buy , title="buy", text="buy", location=location.belowbar, style=shape.labelup, size=size.tiny, color=green, textcolor=white, transp=0)
plotshape(sell , title="sell", text="sell", style=shape.labeldown , location = location.abovebar , color = red, textcolor=white, transp=0)


alertcondition(buy, title="Aşkıncan Tüm Buy", message="Hacı Abi Al Dedi!")
alertcondition(sell, title="Aşkıncan Tüm Sell", message="Hacı Abi Sat Dedi!")
Aşkıncan Tüm
  • 1

1 Answers1

0

Give this a try.

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © greco26
//@version=5
indicator(title = "instagram: askincantum", shorttitle = "instagram: askincantum", overlay = true)



//Mode
RSI = input(80, title="bab")

//RSI
src = close,

ep = 2 * RSI - 1
auc = ta.ema(math.max(src - src[1], 0),ep)
adc = ta.ema(math.max(src[1] - src, 0), ep )
x1 = (RSI - 1) * ( adc * 70 / (100-70) - auc)
ub = x1 >= 0 ? src + x1: src + x1 * (100-70)/70
x2 = (RSI - 1) * ( adc * 30 / (100-30) - auc)
lb = x2 >= 0? src + x2: src + x2 * (100-30)/30

//Affichage
plot(math.avg(ub, lb), color=color.white , linewidth=2, title="Line")


len = input(20,title="Entry")
src1 = input(close, title="Source")
offset = input(0,title="Offset")
out = ta.wma(src1, len)
plot(out, title="Entry", color=color.yellow, linewidth = 2, offset=offset)

buy = ta.crossover(out , math.avg(ub, lb))
sell = ta.crossunder(out, math.avg(ub, lb))


plotshape(buy , title="buy", text="buy", location=location.belowbar, style=shape.labelup, size=size.tiny, color=color.green, textcolor=color.white)
plotshape(sell , title="sell", text="sell", style=shape.labeldown , location = location.abovebar , color = color.red, textcolor=color.white)


alertcondition(buy, title="Aşkıncan Tüm Buy", message="Hacı Abi Al Dedi!")
alertcondition(sell, title="Aşkıncan Tüm Sell", message="Hacı Abi Sat Dedi!")
TFG
  • 3
  • 1