Excecute Python Script When A New Outlook Email Arrives

Question

I have created a python script, which I want to run every time a new email arrives in outlook Inbox. So far I have written this VBA code:

Sub test()
    Shell "C:\Users\dimitrios\Anaconda3\Scripts\activate.bat & python C:\Users\dimitrios\test\outlookconnnectivity.py"
End Sub

The code calls the outlookConnectivity.py script manually. My problem is how I can do that every time a new email arrives.

I found online some solutions, which i tried, but did not work

Why do you need to call an external script? Does it communicate with Outlook in any way? — Eugene Astafiev, Oct 31 '22 at 13:52
try something like https://stackoverflow.com/a/72710085/4539709 — 0m3r, Oct 31 '22 at 19:21

Greedo · Answer 1 · 2022-10-31T12:37:12.413

Try this

Option Explicit

'This "event" runs whenever there is a new email
Private Sub Application_NewMailEx(ByVal EntryIDCollection As String)

    'Declare as generic Object since we don't know what type of NewMail Item we got yet
    Dim entry As Object
    
    'Me refers to ThisOutlookSession, the GetNamespace is just something we always have to do in outlook
    'GetItemFromID gets the mail object which we need to have to check if its an email
    ' or if we want to do something with it like move it to another folder
    Set entry = Me.GetNamespace("MAPI").GetItemFromID(EntryIDCollection)

    'Exit our event handler if this isn't an email - meetings and notifications also may pop up here
    If Not TypeOf entry Is MailItem Then Exit Sub

    'Call the sub that will handle the new email
    ' passing in the email VBA object in case that is important
    OnNewEmail entry
End Sub


'This Sub will be called whenever the Application_NewMailEx event is triggered with a MailItem
Private Sub OnNewEmail(ByVal email As MailItem)
    MsgBox "Email arrived!" & vbNewLine & _
            email.Subject
            
    'Shell "C:\Users\dimitrios\Anaconda3\Scripts\activate.bat & python C:\Users\dimitrios\test\outlookconnnectivity.py"
End Sub

Add that to the ThisOutlookSession Object

Note there are some caveats about when this event runs - see https://learn.microsoft.com/en-us/office/vba/api/outlook.application.newmailex#remarks

Why do you need to to handle both NewMail and NewMailEx events in the code? — Eugene Astafiev, Oct 31 '22 at 12:59
@EugeneAstafiev you don't - `OnNewEmail` is just what I renamed OP's `test` function. It is not an event handler, but a subroutine that I manually call to separate the MailItem filtering logic from the calling portion logic (see last line of `Application_NewMailEx` where I call it). This separation makes the code cleaner but is not required. — Greedo, Oct 31 '22 at 13:11
@EugeneAstafiev you are an outlook expert, can you explain in simple terms when the event would not be triggered, the linked msdn page has a lot of complex caveats which I don't fully understand. Are the `Application_NewMail[Ex]` functions a reliable way to run a script on every incoming email? — Greedo, Oct 31 '22 at 13:16

score 0 · Answer 2 · answered Oct 31 '22 at 13:51

You can call your script in the NewMailEx event handler. This event fires once for every received item that is processed by Microsoft Outlook. The item can be one of several different item types, for example, MailItem, MeetingItem, or SharingItem. The NewMailEx event fires when a new message arrives in the Inbox and before client rule processing occurs. Use the Entry ID returned in the EntryIDCollection string to call the NameSpace.GetItemFromID method and process the item if required.

Excecute Python Script When A New Outlook Email Arrives

2 Answers2