dataweave transformation

Question

I have an input of the following payload for a POST method:

{
  "order": {
    "Column_X": "X",
    "Column_Y": "Y",
    "Column_Z": "Z",
    "Column_W" : {
      "div_1": "some text",
      "div_2": true,
      "div_3": 2
    }
  },
  "mapper": {
    "A": "<order.Column_X>",
    "B": "<order.Column_Z>",
    "C": "Fields or text not mapped to order",
    "C1": "status",
    "D": {
      "D1": "<order.Column_W.div_1>",
      "D2": "<order.Column_W.div_2>",
      "D3": "<order.Column_W.div_3>",
      "D4": "<order.Column_W.div_4>"
    }
  }
}

Here is the expected output mapping with the order object above:

{
   "A":"X",
   "B":"Z",
   "C":"Fields or text not mapped to order",
   "C1":"status",
   "D":{
      "D1":"some text",
      "D2":true,
      "D3":2,
      "D4":null
   }
}

How would I approach this to solve it?

score 1 · Answer 1 · answered Sep 24 '22 at 05:57

This is bit crude approach though hopefully it gives you an idea to query the "order" object a bit dyamically.

%dw 2.0
output application/json
fun returnFromOrder(val : Array) = {
  a:  if (sizeOf(val) ==2) payload."$(val[0])"."$(val[1])"  else payload."$(val[0])"."$(val[1])"."$(val[2])"
}

---
{
    A: returnFromOrder(( payload.mapper.A replace "<" with "" replace ">" with "" splitBy ".")).a,
    B: returnFromOrder(( payload.mapper.B replace "<" with "" replace ">" with "" splitBy ".")).a,
    C: if (returnFromOrder(( payload.mapper.C replace "<" with "" replace ">" with "" splitBy ".")).a == null) payload.mapper.C else "",
    C1: if (returnFromOrder(( payload.mapper.C1 replace "<" with "" replace ">" with "" splitBy ".")).a == null) payload.mapper.C1 else "",
    D: {
        "D1" : returnFromOrder(( payload.mapper.D.D1 replace "<" with "" replace ">" with "" splitBy ".")).a,
        "D2" : returnFromOrder(( payload.mapper.D.D2 replace "<" with "" replace ">" with "" splitBy ".")).a,
        "D3" : returnFromOrder(( payload.mapper.D.D3 replace "<" with "" replace ">" with "" splitBy ".")).a,
        "D4" : returnFromOrder(( payload.mapper.D.D4 replace "<" with "" replace ">" with "" splitBy ".")).a
    }

}

Harshank Bansal · Accepted Answer · 2022-09-24T09:02:21.223

To make it fully dynamic you need two things.

A function that can fetch a value from a dynamic path
Use recursion to build the payload since your mapper itself can contain more Objects that are mapper.

%dw 2.0
output application/json

fun isPath(value) = (value is String) and (value matches "<.+>")

fun getFromPath(json, pathString) = 
    pathString splitBy '.'
        reduce ((path, valueAtPath = json) -> valueAtPath[path])

fun buildUsingMapper(mapper, mappingValues) = 
mapper mapObject ((value, key) -> {
    (key): if(isPath(value)) mappingValues getFromPath value[1 to -2] // eliminate the first "<" and the ending ">". 
            else if(value is Object) buildUsingMapper(value, mappingValues)
            else value
})
---
buildUsingMapper(payload.mapper, payload - "mapper") // you can also pass the full payload instead of payload - "mapper". I did it here to show that the second parameter does not necessarily need the mapper object within.

I have assumed there are no arrays that will have these dynamic path in mapper, Or the dynamic paths will include accessing an array element dynamically.

This is well done! What does the 'json' accumulator do? in the getFromPath argument? json is not a keyword, did not quite get it. — Mio Figlio, Sep 24 '22 at 19:50
Yes, it is just a variable name can be anything. Idea is to initialise accumulator value with the input json. Then because the path string is split the overall expression will result in, for example, `payload['order']` in its first iteration then this order json in the payload will become the new accumulator. In the next iteration it will be `payload[order][COLUMNX]`. This is how it will give the result — Harshank Bansal, Sep 25 '22 at 05:32

score -1 · Answer 3 · answered Sep 24 '22 at 05:49

I hope this is what you are looking for.

%dw 2.0
output application/json
---
{
    A: payload.order.Column_X,
    B: payload.order.Column_Z,
    C: payload.mapper.C,
    C: payload.mapper.C1,
    D: {
        D1: payload.order.Column_W.div_1,
        D2: payload.order.Column_W.div_2,
        D3: payload.order.Column_W.div_3,
        D4: payload.order.Column_W.div_4
    }
}

Output:
{
  "A": "X",
  "B": "Z",
  "C": "Fields or text not mapped to order",
  "C": "status",
  "D": {
    "D1": "some text",
    "D2": true,
    "D3": 2,
    "D4": null
  }
}

dataweave transformation

3 Answers3

Linked

Related