OCaml print statements

Question

Is it possible to put print statements for debugging/testing in blocks of code?

For example, in Java you can use System.out.println("") in the middle of methods to check variables or other things.

But in OCaml, would a command like print_string work? Wouldn't it return a value of type unit, thus causing an error, instead of allowing you to print it?

Ray Toal · Accepted Answer · 2019-10-19T03:03:16.897

22

You will be fine if you embed the print in an expression sequence.

UPDATE

Here is a concrete example, because the answer above was rather short and, well, answers with links only are not good answers. It is the classic tail-recursive formulation of factorial (yeah, boring, but familiar):

# let fac n =
  let rec f i n acc =
    if i >= n
    then acc
    else (Printf.printf "%8d%8d%8d\n" i n acc; f (i+1) n ((i+1)*acc))
  in
    f 0 n 1;;
val fac : int -> int = <fun>
# fac 5;;
       0       5       1
       1       5       1
       2       5       2
       3       5       6
       4       5      24
- : int = 120

Here you can see the side-effects of the print, but the result still turned out to be 120 as expected.

edited Oct 19 '19 at 03:03

answered Sep 11 '11 at 23:36

Ray Toal

86,166
18
182
232

Great, thank you so much! This was exactly what I was looking for. Are expression sequences usually used for anything else, or is this the main usage of them? I guess you can also use it to change values of variables? – dxu Sep 12 '11 at 17:25
Yes, anything that requires updating state, such as updating the value of references, is generally handled this way. There is a very nice and detailed discussion of this [here](http://caml.inria.fr/pub/docs/oreilly-book/html/book-ora028.html), see the section "Sequence". – Ray Toal Sep 12 '11 at 17:51

score 13 · Answer 2 · answered Sep 12 '11 at 01:02

13

Since OCaml isn't a pure functional language, there are many ways to do this. Here is the way I write this kind of code, just for a concrete example.

let rec mylength list =
(* DEBUG *)
let () = Printf.printf "mylength here, null list: %b\n%!" (list = [])
in
(* DEBUG *)
    match list with
    | [] -> 0
    | _ :: rest -> 1 + mylength rest

After it works you can remove the stuff inside the (* DEBUG *) comments.

Note the use of %! to flush the buffer. If you do a lot of debugging with printf (as I do), it's really useful to learn about this.

answered Sep 12 '11 at 01:02

Jeffrey Scofield

65,646
2
72
108

it would be simpler to write `(* DEBUG *) Printf.printf "mylength here, null list: %b\n%!" (list = []); (* DEBUG *)` – newacct Sep 12 '11 at 05:28
1

Sure; like I said I'm just showing the way I really write it. I'm shy about using semicolons outside of parens because of the many precedences I have left to learn. – Jeffrey Scofield Sep 12 '11 at 06:12

Matthias Braun · Answer 3 · 2022-12-10T17:26:03.740

Here's a simple example that shows that expression sequences as mentioned in Ray Toal's answer don't necessarily need parentheses around them:

let get_a_string =
  let a_string = "a string" in
  (* The semicolon causes the return value of the statement to be discarded *)
  Printf.printf "Debug: %s\n" a_string;
  a_string

let () = Printf.printf "Result: %s\n" get_a_string

Another way to discard a function's return value is ignore:

ignore (Printf.printf "Debug info");

OCaml print statements

3 Answers3