Filter for triples in default graph (outside all named graphs) with SPARQL

Question

In the below query I extract all entities with class :Entity, regardless of whether they live inside a specific context (named graph) or not.

SELECT ?s
WHERE {
    ?s a :Entity .
}

I would like to filter among these entities, to keep only those that don't live inside any named graph, i.e., only the entities that exist outside all named graphs (EDIT: I guess the correct terminology is that I want to search for triples only in the default graph).

How can I do this?

Try something like: `SELECT ?s WHERE {?s a :Entity FILTER NOT EXISTS {GRAPH ?g {?s ?p ?o}}}` If you also want `?s` to not exists as an object/predicate, then you can do a `UNION` inside the negation. — Valerio Cocchi, Jul 07 '22 at 20:04
Awesome, this hadn't occurred to me. If you want to post it as an answer I'll accept it without delay. — gaspanic, Jul 07 '22 at 21:44

score 2 · Accepted Answer · answered Jul 08 '22 at 09:13

You can take advantage of the FILTER NOT EXISTS (see here).

In particular, you are looking for resources (I assume IRIs) that exists in the default graph, but not in any named graphs.

So a query like this will work:

SELECT ?s
WHERE {
 ?s a :Entity
FILTER NOT EXISTS {
 GRAPH ?g {
  ?s ?p ?o 
  }
 }
}

This is saying that ?s is not the subject of any triple in any named graph. We can extend the query above to include the case where ?s is not the object of any triple too:

SELECT ?s
WHERE {
 ?s a :Entity
FILTER NOT EXISTS {
 GRAPH ?g {
  {?s ?p ?o}
  UNION
  {?x ?p ?s}
   }
  }
}

Filter for triples in default graph (outside all named graphs) with SPARQL

1 Answers1