table counterpart of column_ifexists()

Question

We do have a function column_ifexists() which refers to a certain column if it exists, otherwise it refers to another option if we provide. Is there a similar function for table? I want to refer to a table and run some logic against it in the query , if the table exists , but if it doesn't exist, there shouldn't be a failure -- it should simply return no data.

e.g.

table_ifexists('sometable') | ...<logic>...

Similar to : https://stackoverflow.com/questions/55575717/check-if-a-table-exists-in-kusto-language — Ramachandran.A.G, Jun 15 '22 at 05:23
Answered, however this may indicate a problematic data engineering flow. — David דודו Markovitz, Jun 15 '22 at 12:58

David דודו Markovitz · Answer 1 · 2022-06-15T13:07:38.333

Please note that the fields referenced in the query should be defined in the dummy table, otherwise in case of non-existing table, the query will yield an exception

Failed to resolve scalar expression named '...'

In the following example these fields are StartTime, EndTime & EventType

Table exists

let requested_table = "StormEvents";
let dummy_table = datatable (StartTime:datetime, EndTime:datetime, EventType:string)[];
union isfuzzy=true table(requested_table), dummy_table
| where EndTime - StartTime > 30d
| summarize count() by EventType

EventType	count_
Drought	1635
Flood	20
Heat	14
Wildfire	4

Fiddle

Table does not exist

let requested_table = "StormEventsXXX";
let dummy_table = datatable (StartTime:datetime, EndTime:datetime, EventType:string)[];
union isfuzzy=true table(requested_table), dummy_table
| where EndTime - StartTime > 30d
| summarize count() by EventType

EventType	count_

Fiddle

See updated answer – David דודו Markovitz Jun 15 '22 at 12:57 — David דודו Markovitz, Jun 15 '22 at 12:57

table counterpart of column_ifexists()

1 Answers1

Table exists

Table does not exist