GROUP BY and Aggregation on Vector of maps - Clojure

Question

I have data that looks like this

(def a [{:firmAccount "MSFT" :Val 10  :PE 3 }  
        {:firmAccount "MSFT" :Val 15  :PE 4} 
        {:firmAccount "GOG" :Val 15 :PE 3} 
        {:firmAccount "YAH" :Val 8 :PE 1}])

I want to group by on :firmAccount and then SUM the :Val and :PE for each firm account and get something like

 [{:firmAccount "MSFT" :Val 25 :PE 7}
  {:firmAccount "GOG" :Val 15 :PE 3}    
  {:FirmAccount "YAH" :Val 8 :PE 1}]

It is really a trivial thing and in SQL I would not even think twice but since I am learning clojure please bear with me

score 8 · Accepted Answer · edited Mar 28 '19 at 03:52

8

Clojure.core has a built-in group-by function. The solution becomes a little ugly by the presence of both text and int vals in the maps.

(for [m (group-by :firmAccount a)]
   (assoc (apply merge-with + (map #(dissoc % :firmAccount) (val m)))
          :firmAccount (key m)))

edited Mar 28 '19 at 03:52

Nathan Davis

5,636
27
39

answered Aug 26 '11 at 12:03

mac

9,885
4
36
51

1

Thanks a lot. It works well for me and it is very succinct. Also the answer made me aware of how to use assoc , merge-with , apply , dissoc , group-by and map in one single example which is awesome . – Ash Aug 26 '11 at 21:44

score 6 · Answer 2 · answered Aug 28 '11 at 01:42

6

And for completeness here's an alternate version that uses map:

(map (fn [[firmAccount vals]] 
   {:firmAccount firmAccount 
    :Val (reduce + (map :Val vals)) 
    :PE (reduce + (map :PE vals))}) 
  (group-by :firmAccount a))

answered Aug 28 '11 at 01:42

user499049

564
2
6

Interesting , one. Thanks very much – Ash Aug 28 '11 at 14:52

score 1 · Answer 3 · edited Mar 28 '19 at 03:50

1

Try creating a new map array or map of maps with the same structure. You can write a function to add elements to this new map that sums that fields if the :firm-account exists. Maybe a map like this?

(def a {"MSFT" {:Val 25  :PE 7 }
        "GOG" {:Val 15 :PE 3} 
        "YAH" {:Val 8 :PE 1}})

With a personalized add function like:

(add-to-map [element map]
  (if (contains? (find-name element))
    {map (add-fields element (find (find-name element)))}
    {map element}))

edited Mar 28 '19 at 03:50

Nathan Davis

5,636
27
39

answered Aug 26 '11 at 11:52

Pedro Montoto García

1,672
2
18
38

Well, if you use the add function I sketched here you don't need to change the structure. Use this ideas how you please. – Pedro Montoto García Aug 26 '11 at 11:57
The change is necessary due to the datastructure in the question. The structure you use in your answer is the requested answer, not the required input. – mac Aug 26 '11 at 17:39

score 0 · Answer 4 · answered Jun 24 '20 at 10:01

It's a matter of style, but I find using thread-last macro (->>) is easier to read.

(->> a
     (group-by :firmAccount)
     (map (fn [[firmAccount vals]]
             {:firmAccount firmAccount 
              :Val (reduce + (map :Val vals)) 
              :PE (reduce + (map :PE vals))})

GROUP BY and Aggregation on Vector of maps - Clojure

4 Answers4