CMake custom command to generate a non-config file

Question

I've read:

and I want to do something similar, but rather than copying a file, I want to generate a file. If that wasn't in a custom command, I would write:

file(WRITE "generated.c" "int main() { return 0; }")

but it doesn't seem like cmake -E supports this directly. What should I do (other than run something platform-dependent)?

Alex Reinking · Accepted Answer · 2021-10-25T23:15:20.803

1

Use CMake's script mode (-P). In CMakeLists.txt:

cmake_minimum_required(VERSION 3.21)
project(test)

file(
  GENERATE
  OUTPUT "gen.cmake"
  CONTENT [[
cmake_minimum_required(VERSION 3.21)
file(WRITE "${OUT}" "int main() { return 0; }")
]])

add_custom_command(
  OUTPUT generated.c
  COMMAND ${CMAKE_COMMAND} -DOUT=generated.c 
          -P gen.cmake
  DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/gen.cmake"
)

add_executable(main "${CMAKE_CURRENT_BINARY_DIR}/generated.c")

Note that if the file you generate has configuration-dependent contents, then you must include $<CONFIG> somewhere in the file name. See the docs here for more detail: https://cmake.org/cmake/help/latest/command/file.html#generate

edited Oct 25 '21 at 23:15

answered Oct 25 '21 at 22:24

Alex Reinking

16,724
5
52
86

And can't I inline my script somehow? – einpoklum Oct 25 '21 at 22:40
@einpoklum - edited... this way you can also use generator expressions in the script. – Alex Reinking Oct 25 '21 at 23:15
Ah, right, should have thought of that... it's super-convoluted though :-P – einpoklum Oct 26 '21 at 05:43
Integrating this into a larger of script of mine, I'm having trouble preventing `generated.c` from being repeatedly generated. – einpoklum Oct 26 '21 at 17:57
... and I've now asked a follow-up. – einpoklum Oct 26 '21 at 19:23

CMake custom command to generate a non-config file

1 Answers1