Problem using FetchContent_Declare together with shared library

Question

I'm having problem using FetchContent_Declare with a shared library. I'm trying to apply a modular design (instead of creating one mega-repository with 20 modules I'm allocating a dedicated repository to each module). I'm trying to use FetchContent_Declare in order to link dependant modules together (I'm not a fan of git-submodules since those require that user manually initialises them). The problem I'm having is that the DLL generated by the project fetched via the mentioned function isn't copied to the binary output of the parent project. Here is a dependency graph to make it more clear.

Repo A:
- bin
- bin-etc
- lib
- include
    - project_a
        .. header files ..
- src
   - CMakeLists.txt : 1
   .. source files ..
- CMakeLists.txt : 2

Repo B: Includes A
- bin
- bin-etc
- lib
- output
    .. cmake files are built from here .. 
    - _deps
        - project_a-src
            - bin 
                .. here the DLL file is being generated .. 
- include
    - project_a
        .. header files ..
- src
   - CMakeLists.txt : 3
   .. source files ..
- CMakeLists.txt : 4

The DLL file is being generated in ./output/_deps/project_a-src/bin instead of ./bin.

Here are my CMakeLists.txt files:

# CMakeLists.txt : 1
cmake_minimum_required(VERSION 3.16)

set(PROJECTNAME project_a)
set(PROJECTDIR "${CMAKE_CURRENT_SOURCE_DIR}")

file(GLOB_RECURSE inc "${CMAKE_CURRENT_SOURCE_DIR}/../include/*.hpp")
file(GLOB_RECURSE src "${CMAKE_CURRENT_SOURCE_DIR}/*.cpp")

source_group(TREE "${CMAKE_CURRENT_SOURCE_DIR}/../include" FILES ${inc})
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} FILES ${src})

if (MSVC)
    add_compile_options(/W3) # warning level 3
    add_compile_options(/MP) # Multi-processor compilation
endif()

add_library(
    ${PROJECTNAME}
    SHARED
    ${inc}
    ${src}
    )

target_include_directories(${PROJECTNAME} PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}/../include/")

# CMakeLists.txt : 2 and 4

cmake_minimum_required(VERSION 3.16)

set_property(GLOBAL PROPERTY USE_FOLDERS ON)

set(CMAKE_SYSTEM_VERSION 10.0.19041.0)

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/bin-etc")
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/lib")
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/bin")

project(project_a LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED)

add_subdirectory(src)

# CMakeLists.txt : 3
cmake_minimum_required(VERSION 3.16)

set(PROJECTNAME project_b)
set(PROJECTDIR "${CMAKE_CURRENT_SOURCE_DIR}")

file(GLOB_RECURSE inc "${CMAKE_CURRENT_SOURCE_DIR}/../include/*.hpp")
file(GLOB_RECURSE inc_src "${CMAKE_CURRENT_SOURCE_DIR}/*.hpp")
file(GLOB_RECURSE src "${CMAKE_CURRENT_SOURCE_DIR}/*.cpp")

source_group(TREE "${CMAKE_CURRENT_SOURCE_DIR}/../include" FILES ${inc})
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} FILES ${inc_src})
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} FILES ${src})

if (MSVC)
    add_compile_options(/W3) # warning level 3
    add_compile_options(/MP) # Multi-processor compilation
endif()

add_library(
    ${PROJECTNAME}
    SHARED
    ${inc}
    ${inc_src}
    ${src}
    )

target_include_directories(${PROJECTNAME} PUBLIC "${CMAKE_CURRENT_SOURCE_DIR}/../include/")

include(FetchContent)

FetchContent_Declare(project_a
        GIT_REPOSITORY <REPO LINK>
        GIT_TAG master)

FetchContent_MakeAvailable(project_a)

target_link_libraries(${PROJECTNAME} project_a)

What would be the solution to this problem? Should I use another approach for the design like this? Is adding a simple copy command to cmake the right solution?

score 1 · Accepted Answer · answered Oct 01 '21 at 12:40

Variables like CMAKE_RUNTIME_OUTPUT_DIRECTORY affects on the output directory for all further created libraries ... unless the variable is changed.

The project_a in CMakeLists.txt(2) does

set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/bin")

unconditionally, so it changes the variable even if it is built as a subproject (with FetchContent).

Generally, any project in its root CMakeLists.txt could check, whether it is actually top-level project. And perform some settings only in case it is:

cmake_minimum_required(VERSION 3.21)

project(project_a LANGUAGES CXX)

if (PROJECT_IS_TOP_LEVEL)
  # Do global settings only if we are top-level project.
  set_property(GLOBAL PROPERTY USE_FOLDERS ON)

  set(CMAKE_SYSTEM_VERSION 10.0.19041.0)

  set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/bin-etc")
  set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/lib")
  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/bin")
endif()

# Other settings are treated as project-specific,
# so could be done in "subproject mode" too.
set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED)

add_subdirectory(src)

Note, that variable PROJECT_IS_TOP_LEVEL appears only in CMake 3.21. For detect, whether the project is top-level in older CMake versions, consult that question and its answers: How to detect if current scope has a parent in CMake?.

That solves my issue. But I would still like to know if there are better aproaches. — Marcin Poloczek, Oct 01 '21 at 13:04

Problem using FetchContent_Declare together with shared library

1 Answers1