Z80 function called by Joystick button prints extra strings instead of the expected one

Question

While exploring joystick connection to the Z80 games I've got this code, which should print 1 letter when I press Up, Left or Right. But for some reason when I press Left it prints lru, when I press Right it prints ru, and u after pressing Up.

            org 32768

    loop    ld bc,31        ; Kempston joystick port.

            in a,(c)        ; read input.
            and 2           ; check "left" bit.
            call nz,joyl    ; move left.
            in a,(c)        ; read input.
            and 1           ; test "right" bit.
            call nz,joyr    ; move right.
            in a,(c)        ; read input.
            and 8           ; check "up" bit.
            call nz,joyu    ; move up.
            in a,(c)        ; read input.
            and 4           ; check "down" bit.

            halt
            jp loop

    joyl    ld de,sl        ; address of string
            ld bc,eostrl-sl ; length of string to print
            call 8252
            ret

    joyr    ld de,sr
            ld bc,eostrr-sr
            call 8252
            ret

    joyu    ld de,su
            ld bc,eostru-su
            call 8252
            ret

    sl      defb "l"
    eostrl  equ $
    sr      defb "r"
    eostrr  equ $
    su      defb "u"
    eostru  equ $

Three different "variables" with unique string length labels, but why calling joyl prints all three letters instead of one?

score 4 · Accepted Answer · answered Aug 27 '21 at 18:14

4

The subroutines change the value of the BC register so if one of them is called the subsequent IN A,(C) instructions will read the wrong port.

Put a LD BC,31 before every IN A,(C) to fix this. Or you could save and restore BC in the subroutines with a push and pop like so:

joyu    push bc
        ld de,su
        ld bc,eostru-su
        call 8252
        pop bc
        ret

answered Aug 27 '21 at 18:14

George Phillips

4,564
27
25

Thanks! Is it correct that the second method is more efficient as it does extra copy-paste only when button is pressed, while the 1'st method does `LD BC,31` 3 extra times every singe iteration of the loop?! – Alexey Aug 27 '21 at 18:33
2

@Alexey: Yes for performance of the polling loop, and also for code-size I think (push/pop bc are 1 byte each, but ld bc, immediate is 3 if I'm reading https://clrhome.org/table/ correctly). Each function only has one call-site, right? Performance here is just how fast you can poll the joystick inputs, and that's human driven so probably slow compared to CPU cycles when you're just looping without making any calls. For worst-case-latency performance from joystick input to when you poll for the next input, that would include both the push and pop, vs. all the LDs until the other bit to see. – Peter Cordes Aug 27 '21 at 19:12

Z80 function called by Joystick button prints extra strings instead of the expected one

1 Answers1