Date Table created with M is imported as an Expression

Question

I am using SSAS Tabular 2019 and I have had no problem in loading my views or tables, but this time instead of loading a Date table from SQL Server I created my own Date table using custom M code, but it appears that the date table is being imported as an Expression and not as a table. Here is a screenshot:

Here is my M code:

let
    Source = ( StartDate as date, EndDate as date ) as table =>
    let
        DateTable = 
            let 
                StartDateNumber         = Number.From ( Date.StartOfYear ( StartDate ) ), 
                EndDateNumber           = Number.From ( Date.AddYears ( Date.EndOfYear ( EndDate ), 1 ) ),
                DateList                = { StartDateNumber..EndDateNumber },
                ToTable                 = Table.FromList ( DateList, Splitter.SplitByNothing() ),
                ToDateType              = Table.TransformColumnTypes ( ToTable, { "Column1", type date } ),
                RenameToDate            = Table.RenameColumns ( ToDateType, { "Column1", "Date" } ) 
            in 
                RenameToDate,

        // Day related fields are created here
        Day_Fields = 
            let
                Add_Day_Name            = Table.AddColumn ( DateTable, "Weekday Name", each Date.DayOfWeekName ( [Date] ), type text ),
                Add_Day_Number          = Table.AddColumn ( Add_Day_Name, "Weekday Number", each Date.DayOfWeek ( [Date] ), Int64.Type )
            in
                Add_Day_Number,

        // Month related fields are created here
        Month_Fields = 
            let
                Add_Month_Name          = Table.AddColumn ( Day_Fields, "Month Name", each Date.MonthName ( [Date] ), type text ),
                Add_Month_Number        = Table.AddColumn ( Add_Month_Name, "Month Number", each Date.Month ( [Date] ), Int64.Type ),
                Add_Month_Initials      = Table.AddColumn ( Add_Month_Number, "Month Initials", each Text.Start ( [Month Name], 3 ), type text )
            in
                Add_Month_Initials,

        // Year Related Fields are Create Here

        Year_Fields = 
            let
                Add_Year                = Table.AddColumn ( Month_Fields, "Calendar Year Number", each Date.Year ( [Date] ), Int64.Type ),
                Add_Year_Text           = Table.AddColumn ( Add_Year, "Calendar Year", each "CY " & Text.From ( Date.Year ( [Date] ) ), type text )
            in
                Add_Year_Text
    in
        Year_Fields
in
    Source

Can you please confirm what is happening here?