How get compiled date of a dll file?

Question

I'm using this code to capture compilation date of a executable (.exe). I'm searching a solution to achieve the same to a .dll file. When this code is inserted in a dll project and injected/or using exported function in some executable (.exe), the compilation date retrieved is of executable and not of dll.

function GetExeBuildTime: TDateTime;
var
  LI: TLoadedImage;
{$IF CompilerVersion >= 26.0}
  m: TMarshaller;
{$IFEND}
  timeStamp: Cardinal;
  utcTime: TDateTime;
begin
{$IF CompilerVersion >= 26.0}
  Win32Check(MapAndLoad(PAnsiChar(m.AsAnsi(ParamStr(0)).ToPointer), nil, @LI,
    False, True));
{$ELSE}
  Win32Check(MapAndLoad(PAnsiChar(AnsiString(ParamStr(0))), nil, @LI,
    False, True));
{$IFEND}
  timeStamp := LI.FileHeader.FileHeader.TimeDateStamp;
  UnMapAndLoad(@LI);

  utcTime := UnixToDateTime(timeStamp);
  Result := TTimeZone.local.ToLocalTime(utcTime);
end;

Usage:

FormatDateTime('dd/mm/yyyy', GetExeBuildTime);

DLLs use the same PE format so you find the build date the exact same way for DLLs and EXEs — David Heffernan, Jul 29 '21 at 11:50
See [this](https://stackoverflow.com/questions/2043/can-a-windows-dll-retrieve-its-own-filename) to retrieve the path to the DLL. — Olivier, Jul 29 '21 at 12:40

score 3 · Accepted Answer · answered Jul 29 '21 at 12:31

Your code example is using ParamStr(0) to retrieve path to the executable file of your application that is the passed to MapANdLoad function to load PE Image of the executable into memory.

You need to replace the ParamStr(0) with the file location of your DLL file in order to retrieve this information from your DLL file.

Here is your function modified so that it accepts path to the executable or DLL as input parameter.

function GetExeBuildTime(ExecutablePath: String): TDateTime;
var
  LI: TLoadedImage;
{$IF CompilerVersion >= 26.0}
  m: TMarshaller;
{$IFEND}
  timeStamp: Cardinal;
  utcTime: TDateTime;
begin
{$IF CompilerVersion >= 26.0}
  Win32Check(MapAndLoad(PAnsiChar(m.AsAnsi(ExecutablePath).ToPointer), nil, @LI,
    False, True));
{$ELSE}
  Win32Check(MapAndLoad(PAnsiChar(AnsiString(ExecutablePath)), nil, @LI,
    False, True));
{$IFEND}
  timeStamp := LI.FileHeader.FileHeader.TimeDateStamp;
  UnMapAndLoad(@LI);

  utcTime := UnixToDateTime(timeStamp);
  Result := TTimeZone.local.ToLocalTime(utcTime);
end;

Hint: this is unbound to the platform - you can also check a 64 bit DLL in your 32 bit EXE with this. OS/2 and 16 bit DLLs/EXEs don't have such timestamp at all. — AmigoJack, Jul 30 '21 at 10:42

How get compiled date of a dll file?

1 Answers1