XSLT 2.0 group-adjacent based on attribute value

Question

I am trying to generate XML using XSLT, I want to generate a string when two consecutive nodes has an attribute value as Position="A", I want to add a hyphen(-) in the string, otherwise I want to concatenate node value. I tried using group-adjacent with attribute value, but it fails on empty attribute node. I tried adding string() for attribute value, but not worked.

<xsl:variable name="columnId">
  <xsl:for-each-group select="CabinLayout/Columns" group-adjacent="string(@Position)">
    <xsl:value-of select="current-group()"/>
  </xsl:for-each-group>
</xsl:variable>
<ColumnID><xsl:value-of select="translate($columnId,' ','-')"/></ColumnID>

Below is the sample input and desired output

<CabinLayout>
  <Columns Position="W">A</Columns>
  <Columns>B</Columns>
  <Columns Position="A">C</Columns>
  <Columns Position="A">D</Columns>
  <Columns>E</Columns>
  <Columns Position="W">F</Columns>
</CabinLayout>

Output- ABC-DEF

<CabinLayout>
  <Columns Position="W">A</Columns>
  <Columns>B</Columns>
  <Columns>C</Columns>
  <Columns Position="A">D</Columns>
  <Columns>E</Columns>
  <Columns>F</Columns>
  <Columns>G</Columns>
  <Columns>H</Columns>
  <Columns>J</Columns>
  <Columns Position="W">K</Columns>
</CabinLayout>

Output : ABCDEFGHJK

<CabinLayout>
  <Columns Position="W">A</Columns>
  <Columns>B</Columns>
  <Columns Position="A">C</Columns>
  <Columns Position="A">D</Columns>
  <Columns>E</Columns>
  <Columns>F</Columns>
  <Columns Position="A">G</Columns>
  <Columns Position="A">H</Columns>
  <Columns>J</Columns>
  <Columns Position="W">K</Columns> 
</CabinLayout>

Output : ABC-DEFG-HJK

All below solutions worked well, will go through each and try with multiple scenarios. Thank you. — Umaimath Thonikkadavan, Jun 11 '21 at 08:47

score 4 · Answer 1 · answered Jun 10 '21 at 15:29

I think the following group-ending-with solves that:

  <xsl:template match="CabinLayout">
    <ColumnID>
      <xsl:value-of separator="-">
        <xsl:for-each-group select="Columns" group-ending-with="Columns[@Position = 'A' and following-sibling::Columns[1][@Position = 'A']]">
          <xsl:sequence select="string-join(current-group(), '')"/>
        </xsl:for-each-group>        
      </xsl:value-of>
    </ColumnID>
  </xsl:template>

score 3 · Accepted Answer · answered Jun 10 '21 at 15:37

I would use the current-grouping-key() and if it is A then make the value separator -, otherwise get the values with an empty string as the separator:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:wd="urn:com.test/bsvc" exclude-result-prefixes="wd">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    
    <xsl:template match="/"> 
        <xsl:variable name="columnId">
            <xsl:for-each-group select="CabinLayout/Columns" group-adjacent="string(@Position)">
                <xsl:choose>
                    <xsl:when test="current-grouping-key()='A'">
                        <xsl:value-of select="current-group()" separator="-"/>
                    </xsl:when>
                    <xsl:otherwise><xsl:value-of select="current-group()" separator=""/></xsl:otherwise>
                </xsl:choose>
            </xsl:for-each-group>
        </xsl:variable>
        <ColumnID><xsl:value-of select="$columnId"/></ColumnID>
    </xsl:template>
    
</xsl:stylesheet>

It worked fine, will try with multiple scenarios. Thank you. — Umaimath Thonikkadavan, Jun 11 '21 at 08:49

Siebe Jongebloed · Answer 3 · 2021-06-10T16:00:08.103

Something like this:

<xsl:stylesheet version="2.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

  <xsl:strip-space elements="*"/>  

  <xsl:template match="/">
    <ColumnID>
      <xsl:for-each-group select="CabinLayout/Columns" group-adjacent="string(@Position)">
        <xsl:choose>
          <xsl:when test="current-group()[@Position]">
            <xsl:value-of select="current-group()" separator="-"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="current-group()" separator=""/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each-group>
    </ColumnID>
      
  </xsl:template>
</xsl:stylesheet>

Thank you for the answer, it worked for given inputs, will cross check with multiple scenarios. — Umaimath Thonikkadavan, Jun 11 '21 at 08:50

XSLT 2.0 group-adjacent based on attribute value

3 Answers3

Linked