adding extra element to a list in terraform if condition is met

Question

I have a list in terraform that looks something like:

array = ["a","b","c"]

Within this terraform file there are two variables called age and gender, and I want to make it so that the list called array has an extra element called "d" if age is equal to 12 and gender is equal to male (i.e. if var.age == 12 && var.gender == 'male' then array should be ["a","b","c","d"], else array should be ["a","b","c"]). Would the following going along the right path, or would I need to use another method?

array = ["a","b","c", var.age == 12 && var.gender == 'male' ? "d" : null]

score 30 · Answer 1 · edited Dec 13 '21 at 14:37

30

There is another way to do that using flatten:

variable = flatten(["a", "b", "c", var.age == 12 ? ["d"] : []])

edited Dec 13 '21 at 14:37

marc_s

732,580
175
1,330
1,459

answered Nov 23 '21 at 22:29

desunit

847
8
12

Made my day -- works for lists of objects too! – Brent Bradburn Aug 12 '22 at 23:35

score 8 · Accepted Answer · answered Jun 09 '21 at 11:04

8

There are few ways you could do it. One way would be (example):

variable "array" {
  default = ["a","b","c"]
}

variable "age" {
  default = 12
}

variable "gender" {
  default = "male"
}

locals {
  array = var.age == 12 && var.gender == "male" ? concat(var.array, ["d"]) : var.array
}

output "test" {
  value = local.array
}

answered Jun 09 '21 at 11:04

Marcin

215,873
14
235
294

2

Curious... what other ways would be? :) – ravenwing Sep 14 '21 at 19:50

Breedly · Answer 3 · 2022-07-05T19:49:20.930

Another approach to the problem in your particular example is removing empty elements at the end of the array.

compact is perhaps the most straightforward, but requires you to rely on using "" as a sentinel value for Emptiness.

From the documentation:

compact takes a list of strings and returns a new list with any empty string elements removed.

> compact(["a", "", "b", "c"])
[
  "a",
  "b",
  "c",
]

I would prefer this over the other answers because it's more idiomatic. I suppose it only works for strings though.

array = compact(["a","b","c", var.age == 12 && var.gender == 'male' ? "d" : ""])`
["a","b","c"] if age != 12 and gender != male
["a","b","c", "d"] if age == 12 and gender == male

Of course the "" element could be anywhere in your list and compact would handle this optionality issue.

I would also be interested in which has the best O() performance. I don't know how compact is implemented underneath the hood, but in general you would either copy elements into a new array or you would be shifting elements into gaps left by removed elements.

I don't expect any other solution to be much better than this. Perhaps concat.

Given that, it probably requires O(n) comparisons + appends, and then takes O(n) space because a new list is created.

adding extra element to a list in terraform if condition is met

3 Answers3