Hide duplicate files in macOS search results?

Question

I don't want to delete duplicate files, but I only want to see one instance of each.

Prioritization among duplicates doesn't matter in this case.

///

The actual scenario:

I want to create a VLC playlist containing every video I have ever downloaded from a particular domain. The files are not well-organized and many exist in more than one location on my computer. Consequently, a Finder search for "Where from" --> [the domain] returns many duplicate files. Which means I can't just drag and drop the search results into VLC without there being many duplicates.

I don't want to deduplicate the files themselves.

How can I make this happen?

How are you searching, and do the videos have the same names? — red_menace, Jun 08 '21 at 19:55
When the videos are the same file, they do have the same names. I have been searching in Finder using the "Where from" parameter, with the source domain as my search term. — CrosswordPuzzlz, Jun 09 '21 at 02:38

Robert Kniazidis · Accepted Answer · 2021-06-09T07:20:21.187

It is not possible to hide duplicates in the Finder search because there is no option for filtering duplicates in the Finder search.

But your job is to search, then create a playlist. This can be done by dragging and dropping your selection onto the next droplet, which you can call "VLC Playlist Creator". (Or turn it into a "Make VLC Playlist" service using Automator). It will filter for you the duplicates and open Save Playlist Dialog of VLC.app.

on open theAliases
    set {namesList, moviesList} to {{}, {}}
    repeat with i from 1 to count theAliases
        set anAlias to item i of theAliases
        tell application "Finder" to set theName to name of anAlias
        if not (namesList contains theName) then
            set end of namesList to theName
            set end of moviesList to anAlias
        end if
    end repeat
    -- try to restart "VLC" to clear old playlist
    if running of application "VLC" then quit application "VLC"
    repeat while running of application "VLC"
        delay 0.1
    end repeat
    -- add movies to playlist
    tell application "VLC"
        open moviesList
        stop
        activate
    end tell
    -- save playlist dialog
    tell application "System Events" to keystroke "s" using command down
    tell application "VLC" to activate
end open

Hide duplicate files in macOS search results?

1 Answers1