ARM templates how to add public IP to dns zone

Question

I'm using arm templates for deployments (preferable bicep). Is there a simple way to add my public ip resource to preexisting DNS zone? Public IP has property named dnsSettings, but it seems that it only can set DNS pointing to azure default domain publicipname.eastus.cloudapp.azure.com, instead of publicipname.customdomain.com.

resource publicIp 'Microsoft.Network/publicIPAddresses@2020-11-01' = {
  location: rg_location
  name: 'pip-example'
  tags: tags_list
  sku: {
    name: 'Standard'
    tier: 'Regional'
  }
  properties:{
    dnsSettings:{
      domainNameLabel: 'publicipname'
      fqdn: 'publicipname.customdomain.com'
    }
    publicIPAllocationMethod: 'Static'
  }
}

Where do you have that DNS zone? In your Azure or in external DNS provider? — Miq, May 28 '21 at 13:57
And please add the term "Bicep" to your question. Otherwise it is misleading. — Kai Walter, Aug 14 '21 at 11:11

Kai Walter · Answer 1 · 2021-08-05T16:11:18.683

You could register the PublicIP resource directly in DNS like:

...
resource dns 'Microsoft.Network/dnsZones@2018-05-01' = {
  name: 'customdomain.com'
  location: 'global'
  properties: {
    zoneType: 'Public'
  }
}

resource dnsEntry 'Microsoft.Network/dnsZones/A@2018-05-01' = {
  name: 'publicipname'
  parent: dns
  properties: {
    TTL: 3600
    targetResource: {
      id: publicIp.id
    }
  }
}

or with the IP address

resource dns 'Microsoft.Network/dnsZones@2018-05-01' = {
  name: 'customdomain.com'
  location: 'global'
  properties: {
    zoneType: 'Public'
  }
}

resource dnsEntry 'Microsoft.Network/dnsZones/A@2018-05-01' = {
  name: 'publicipname'
  parent: dns
  properties: {
    TTL: 3600
    ARecords: [
      {
        ipv4Address: publicIp.properties.ipAddress
      }
    ]
  }
}

ARM templates how to add public IP to dns zone

1 Answers1