VBscript to ping a list of computers

Question

I'm using this VBscript code to ping a list of computers in a notepad and store the ping results in a csv file.

All computers stored in a notepad file are now availables (cmd >>> ping servername), but the results in csv file are all DOWN.

I have tried also stored in notepad file one computer unavailable, but the results ping in a csv file are all DOWN...

Any suggestion?

My code below

dim strInputPath, strOutputPath, strStatus
dim objFSO, objTextIn, objTextOut

strInputPath = "C:\serverlist.txt"
strOutputPath = "C:\output.csv"

set objFSO = CreateObject("Scripting.FileSystemObject")
set objTextIn = objFSO.OpenTextFile( strInputPath,1 )
set objTextOut = objFSO.CreateTextFile( strOutputPath )
objTextOut.WriteLine("computer,status")

Do until objTextIn.AtEndOfStream = True
    strComputer = objTextIn.ReadLine
        if fPingTest( strComputer ) then
             strStatus = "UP"
        else
             strStatus = "DOWN"
        end if
        objTextOut.WriteLine(strComputer & "," & strStatus)
loop

function fPingTest( strComputer )
        dim objShell,objPing
        dim strPingOut, flag
        set objShell = CreateObject("Wscript.Shell")
        set objPing = objShell.Exec("ping " & strComputer)
    strPingOut = objPing.StdOut.ReadAll
    if instr(LCase(strPingOut), "reply") then
           flag = TRUE
        else
           flag = FALSE
        end if
        fPingTest = flag
end function

probably doesn't solve your problem, but instead of looking for `reply`, you should look for `TTL=`. Reason1: `TTL=` is language independent. Reason2: avoid false positives (`Reply from : Destination host unreachable`) — Stephan, Apr 29 '21 at 09:33
@Stephan thanks for reply.. i've changed code using this https://msfn.org/board/topic/104877-vbscript-ping-multiple-ip-addresses-and-machine-names/ — Edward Sheriff Curtis, Apr 29 '21 at 10:48

Hackoo · Accepted Answer · 2021-04-29T22:08:06.433

You can use this function IsOnLine :

dim strInputPath, strOutputPath, strStatus
dim objFSO, objTextIn, objTextOut

strInputPath = "C:\serverlist.txt"
strOutputPath = "C:\output.csv"

set objFSO = CreateObject("Scripting.FileSystemObject")
set objTextIn = objFSO.OpenTextFile( strInputPath,1 )
set objTextOut = objFSO.CreateTextFile( strOutputPath )
objTextOut.WriteLine("computer,status")

Do until objTextIn.AtEndOfStream = True
    strComputer = objTextIn.ReadLine
        if IsOnLine(strComputer) then
             strStatus = "UP"
        else
             strStatus = "DOWN"
        end if
        objTextOut.WriteLine(strComputer & "," & strStatus)
loop
'---------------------------------------------------------------------------------------
Function IsOnLine(strHost)
Dim objPing,objRetStatus
Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery _
("select * from Win32_PingStatus where address = '" & strHost & "'")
For Each objRetStatus In objPing
    If IsNull(objRetStatus.StatusCode) Or objRetStatus.StatusCode <> 0 Then
        IsOnLine = False
    Else
        IsOnLine = True
    End If
Next
End Function
 '---------------------------------------------------------------------------------------

VBscript to ping a list of computers

1 Answers1