0

Gnuplot script:

set palette defined (0 "blue", 100 "green", 500 "red")
splot "data" using 1:2:3 with lines lc palette z

Data file:

1 1 1
1 2 1
1 3 500
1 4 1

This results in something like this:

_/\

What I got, is that the 2 slopes are green.

I want them to be red. Or at least reddish.

I suspect that the coloring strategy is to use the color of the midpoint of the line.

How can I change the coloring strategy? ("color by highest point")

ALTERNATIVE:

If it is not possible this way, it would also be acceptable if it is done with another linecolor option. I have not quite figured it out yet, but I know there is direct coloring.

However, if possible I would prefer a palette-based solution, where I can easily generate a color gradient, and not have to do it manually in the datafile.

Zoltan K.
  • 1,036
  • 9
  • 19

2 Answers2

1

Requires current gnuplot (version 5.4)

Instead of coloring with lc palette, we will do our own lookup in the current palette to get an RGB value for that palette value and then tell the plot command to use that rgb value with lc rgb variable.

The palette(cbvalue) function is new in 5.4, which is why you need a current gnuplot.

Because we are no longer plotting referring to lc palette gnuplot does not autoscale or draw the colorbox by default, so we must explicitly give cbrange.

$DATA << EOD
1 1 1
1 2 1
1 3 500
1 4 1
EOD

set palette defined (0 "blue", 100 "green", 500 "red")
set cbrange [0:500]

highest(z) = (ztmp=zold,zold=z, ztmp>z ? ztmp : z)

zold = NaN
splot $DATA using 1:2:3:( palette(highest($3)) ) with lines lc rgb variable

enter image description here

To avoid having to reinitialize zold before a replot, you might want to include it in the plot statement as an in-line definition:

splot zold=NaN, $DATA using 1:2:3:( palette(highest($3)) ) with lines lc rgb variable
Ethan
  • 13,715
  • 2
  • 12
  • 21
1

In addition to @Ethan's solution for gnuplot 5.4, here is a solution which works for gnuplot 5.0 and with minor modifications even with version 4.6. It uses the plotting style with vectors.

Script: (works with gnuplot>=5.0.0)

### apply linecolor from higher z-value
reset session

$Data <<EOD
1 1 1
1 2 1
1 3 500
1 4 1
EOD

set palette defined (0 "blue", 100 "green", 500 "red")
unset key

splot x1=y1=z1=NaN $Data u (x0=x1,x1=$1,x0):(y0=y1,y1=$2,y0):(z0=z1,z1=$3,z0):\
                   (x1-x0):(y1-y0):(z1-z0):(z0>z1 ? z0 : z1) w vec nohead palette
### end of script

Result:

enter image description here

theozh
  • 22,244
  • 5
  • 28
  • 72