Julia throws undefined error when the variable is defined

Question

I have this simple while loop that uses i = 1 as an index.

global i = 1 
    
    n = rows
    while i <= n
        if prod(isa.(collect((y)[i,:]),Number))==0
            delete!(y,i)
            x_axis = x_axis[1:end .!= i]
            n -= 1
        end
        i += 1
    end

but I'm getting this error:

UndefVarError: i not defined

top-level scope@Local: 23

I even made my i global as per the suggestion on some similar questions on SO but the error persists. I am running this on Pluto.jl so maybe it could be an environment issue.

I think this will work if you do `global i += 1` near the end of your function. — logankilpatrick, Mar 22 '21 at 01:36
Feel free to reach through here for reference: https://docs.julialang.org/en/v1/manual/variables-and-scoping/#Global-Scope — logankilpatrick, Mar 22 '21 at 01:37

Benoit Pasquier · Accepted Answer · 2021-03-22T13:20:13.493

Firstly, note that if you use Julia v1.5+ then you don't need to make i a global (example below with current stable version v1.5.4):

julia> i = 1
1

julia> while i < 5
           println(i)
           i += 1     # <----- this works in Julia v1.5+
       end
1
2
3
4

However, it seems you are using Julia v1.4 of older, in which case I think Logan Kilpatrick gave you the answer: You need to make i a global from inside the while loop's scope. As Logan mentioned, try adding global where you increment i, like in this example from the while function's docs:

julia> i = 1 ;

julia> while i < 5
           println(i)
           global i += 1     # <------------ Try this!
       end
1
2
3
4

Note also that you don't need to specify it's a global if your while loop is inside a function, as in

julia> function foo(istart)
           i = istart
           while i < 5
               println(i)
               i += 1     # <-- 'global' not needed inside a function!
           end
       end
foo (generic function with 1 method)

julia> foo(1)
1
2
3
4

score 0 · Answer 2 · answered Mar 22 '21 at 10:35

You have hitted the "ambiguous soft scope case".

In short: the assignment of a local variable inside a (soft) local scope depends if the code is inside a "REPL context" or not.

For "REPL context" I mean the REPL and all environments that behaves as the REPL in this case, for example Jupyter:

julia> i = 0
julia> while i < 3
         i += 1
         @info i
       end
[ Info: 1
[ Info: 2
[ Info: 3

Instead code from non interactive context like file, eval and Pluto acts like that:

julia> code = """
       i = 0
       while i < 3
         i += 1
         @info i
       end
       """

julia> include_string(Main, code)
┌ Warning: Assignment to `i` in soft scope is ambiguous because a global variable by the same name exists: `i` will be treated as a new local. Disambiguate by using `local i` to suppress this warning or `global i` to assign to the existing global variable.
└ @ string:3
ERROR: LoadError: UndefVarError: i not defined

All of this has been designed to ensure both the convenience of REPL usage and to avoid unwanted side effects of using julia on a large scale.

Full details here.

To fix the problem you may be use global as already suggested or enclose your code inside a function.

score 0 · Answer 3 · answered Mar 24 '21 at 16:08

Pluto implicitly wraps a cell into a function, see https://github.com/fonsp/Pluto.jl/pull/720, therefore the global annotation or explicit wrapping into a function should not be required.

Putting the following into a Pluto cells works for me:

begin
    i = 1
    n = 100
    while i<=n
        if i % 2 == 0
            n -= 1
        end
        i += 1
    end
end

The implicit function wrapping is disabled when macros are used inside a cell (which prevents Pluto to gather reactivity information), therefore the following does not work in Pluto due to the Julia scoping rules:

begin
    i = 1
    n = 100
    while i<=n
        if i % 2 == 0
            n -= 1
        end
        @show i += 1
    end
end

Throws:

UndefVarError: i not defined

top-level scope@Local: 5[inlined]
top-level scope@none:0

Julia throws undefined error when the variable is defined

3 Answers3