How to import package in cmake from vcpkg?

Question

When I vcpkg install simdjson , it returns :

The package simdjson:x64-linux provides CMake targets:

    find_package(simdjson CONFIG REQUIRED)
    target_link_libraries(main PRIVATE simdjson::simdjson simdjson::simdjson-flags simdjson::simdjson-headers)

So I add

    find_package(simdjson CONFIG REQUIRED)
    target_link_libraries(main PRIVATE simdjson::simdjson simdjson::simdjson-flags simdjson::simdjson-headers)

to CMakeLists.txt to use the package simdjson

But when I vcpkg install redis-plus-plus[cxx17] , it returns nothing . What should I do to let cmake use this package ?

Btw you probably only need `simdjson::simdjson`. Vcpkg generates those usage instructions automatically and they tend to include too many targets. — Alex Reinking, Mar 02 '21 at 22:43

score 5 · Accepted Answer · answered Mar 01 '21 at 09:01

Unfortunately, redis-plus-plus doesn't supply CMake config files. Someone should open an issue with upstream. It's honestly pretty unacceptable to not support find_package for your library. Thus, thanks to the authors' negligence, you will have to create an imported target for their library yourself. Here's an example CMakeLists.txt, step by step. We'll start with the standard boilerplate:

cmake_minimum_required(VERSION 3.19)
project(test-redis)

Then we need to find hiredis, which is one of Redis++'s dependencies:

find_package(hiredis REQUIRED)

This will create a target called hiredis::hiredis we'll link to later. Now we'll create a target to hold the Redis++ usage information.

add_library(redis++::redis++ UNKNOWN IMPORTED)

Now we need to actually find the header path and redis++ libraries:

find_path(REDIS_PP_HEADER sw REQUIRED)
find_library(REDIS_PP_LIB redis++ REQUIRED)

And now we can tell CMake that the target we just created manages the library we just found:

set_target_properties(redis++::redis++ PROPERTIES IMPORTED_LOCATION "${REDIS_PP_LIB}")

And finally we can set up the include paths and dependency on Hiredis.

target_include_directories(redis++::redis++ INTERFACE "${REDIS_PP_HEADER}")
target_link_libraries(redis++::redis++ INTERFACE hiredis::hiredis)

We're now ready to use the library like we ought to be able to expect to.

add_executable(main main.cpp)
target_link_libraries(main PRIVATE redis++::redis++)

How to import package in cmake from vcpkg?

1 Answers1