Raku NativeCall to LibX11 screen and display

Question

Fedora 33 Raku

I am trying to use Raku's NativeCall to talk to libX11.so to print out both my screen and my display:

use NativeCall;

class Display is repr('CStruct') { has Pointer $.DisplayPtr };

# libX11.so --> X11
sub XOpenDisplay(Str $name = ':0') returns Display is native('X11') { * }
sub XDefaultScreen(Display $) returns int32 is native('X11') { * }

my Display $display = XOpenDisplay()
    or die "Can not open display";
 
my int $screen = XDefaultScreen($display);

print "display = <" ~ $display ~ ">\n";
print "screen =  <" ~ $screen  ~ ">\n";


$ libX11.pl6
display = <Display<90201160>>
screen =  <0>

Problem. I am missing something about the class syntax as it is showing me a pointer address instead of my display, which I presume to be ":0". Also I thing the class declaration should show a string somewhere.

hobbs · Answer 1 · 2020-12-21T16:48:40.927

You're confusing somewhat a Display, which is an object that you use to interact with X, and a display name, which is a string that you can use to identify and connect to a Display.

Also, you're best off using repr('CPointer'), not repr('CStruct') for an XDisplay *, since the Xlib documentation says that it should be treated as an opaque pointer and everything accessed through functions, and translating the whole struct to Raku would be laborious (and not very useful).

Since it is like an object in that way, you have the option of encapsulating all of the Xlib functions inside of the Display class, and wrapping them in methods, as shown in the pointers section of the NativeCall docs. My translation of the code you have so far to this style would be:

use NativeCall;

class Display is repr('CPointer') {
  sub XOpenDisplay(Str) returns Display is native('X11') { * }
  method new(Str $name = ':0') {
    XOpenDisplay($name);
  }

  # You can wrap a libX11 function in a method explicitly, like this...
  sub XDisplayString(Display) returns Str is native('X11') { * }
  method DisplayString {
    XDisplayString(self);
  }

  # Or implicitly, by putting 'is native' on a method declaration 
  # and using 'is symbol' to match the names
  # (self will be passed as the first argument to the libX11 function)
  method DefaultScreen() returns int32 is native('X11') 
    is symbol('XDefaultScreen') { * }

  method Str {
    "Display({ self.DisplayString })";
  }
}

my Display $display .= new
    or die "Can not open display";

my int $screen = $display.DefaultScreen;

print "display = <" ~ $display ~ ">\n";
print "screen =  <" ~ $screen  ~ ">\n";

I provided a method Str for Display, so that it can be printed directly, but again, don't confuse the object with the string that you use to get hold of one. You would go on from here by adding more methods to Display, as well as defining Screen, Window, etc. in the same way. You don't have to do it this way -- you're free to define the subs publicly and use calls to XOpenDisplay and everything else, as if you were writing C, but the OO style tends to be a bit cleaner. The choice is yours.

I'm sure that `method DefaultScreen () returns int32 is native is symbol {*}` would work. No need to create a simple wrapper when NativeCall can already handle that for you. Also I would consider putting the `XOpenDisplay` sub declaration inside of `new` as that should be the only method that uses it. — Brad Gilbert, Dec 21 '20 at 16:35
@BradGilbert okay. I haven't done this before, I was just following the doc materials. I can tweak a bit :) — hobbs, Dec 21 '20 at 16:37
@BradGilbert a method with `is native` will put invocant in the first argument? — hobbs, Dec 21 '20 at 16:38
A Method always takes the object it was called on as it's first argument. This is also part of the tests for NativeCall. [22-method.t](https://github.com/rakudo/rakudo/blob/master/t/04-nativecall/22-method.t) [22-method.c](https://github.com/rakudo/rakudo/blob/master/t/04-nativecall/22-method.c) — Brad Gilbert, Dec 21 '20 at 16:43

jjmerelo · Answer 2 · 2020-12-21T08:06:37.200

5

In the comments @hobbs has pointed me in the right direction, by suggesting a new function, XDisplayString, that can actually be used to turn a pointer into a string describing the display, without actually needing to go into the full structure of the pointer. So this is how it would go:

use NativeCall;

class Display is repr('CPointer') {};

# libX11.so --> X11
sub XOpenDisplay(str $name = ':0') returns Display is native('X11') { * }
sub XDefaultScreen(Str $) returns int32 is native('X11') { * }
sub XDisplayString(Display $display) returns Str is native('X11') { * }

my $display = XOpenDisplay() or die "Can not open display";
my Str $displayStr = XDisplayString($display);
my int $screen = XDefaultScreen( $displayStr );

print "display = <" ~ $displayStr ~ ">\n";
print "screen =  <" ~ $screen  ~ ">\n";

That would return:

display = <:0>
screen =  <64>

At least in my machine. The key here is that you're actually ising the right way of describing the screen, at least as far as XDisplayString is concerned, so you turn the original Pointer into a Str, and then you sna use it in whatever X* need a string description of the display.

edited Dec 21 '20 at 08:06

answered Dec 21 '20 at 07:16

jjmerelo

22,578
8
40
86

1

`XOpenDisplay` returns a `Display *` and everything you could want to do with a display is accessible by function calls taking a `Display *` (Xlib.h even comments "A Display should be treated as opaque by application code."). So isn't there a way to treat it as an opaque pointer instead of mapping the struct internals to Raku-land? – hobbs Dec 21 '20 at 07:27
1

(haven't done this before, but it seems like `is repr('CPointer')` fits the bill) – hobbs Dec 21 '20 at 07:29
@hobbs you can't `unbox to a native string` in that case (doing `class Display is repr('CPointer') {};` . If you want to obtain any information at all from it, you need to declare it in full. – jjmerelo Dec 21 '20 at 07:50
2

Yes, but that's a mistaken thing to do in the first place — the correct thing is to call `XDisplayString(Display *dsp)`. Which could of course be bound to `method gist` or `method Str` or anything you please. – hobbs Dec 21 '20 at 07:53
I guess I'll have to see if I can get this working enough to write my own answer. – hobbs Dec 21 '20 at 07:55
2

Glad to help - I also wrote my own taking a slightly different approach. The NativeCall tutorial is amazingly good! – hobbs Dec 21 '20 at 08:31

Raku NativeCall to LibX11 screen and display

2 Answers2