Can I delete a field in awk?

Question

This is test.txt:

0x01,0xDF,0x93,0x65,0xF8
0x01,0xB0,0x01,0x03,0x02,0x00,0x64,0x06,0x01,0xB0
0x01,0xB2,0x00,0x76

If I run awk -F, 'BEGIN{OFS=","}{$2="";print $0}' test.txt the result is:

0x01,,0x93,0x65,0xF8
0x01,,0x01,0x03,0x02,0x00,0x64,0x06,0x01,0xB0
0x01,,0x00,0x76

The $2 wasn't deleted, it just became empty. I hope, when printing $0, that the result is:

0x01,0x93,0x65,0xF8
0x01,0x01,0x03,0x02,0x00,0x64,0x06,0x01,0xB0
0x01,0x00,0x76

score 27 · Answer 1 · edited Dec 14 '20 at 06:25

27

All the existing solutions are good though this is actually a tailor made job for cut:

cut -d, -f 1,3- file

0x01,0x93,0x65,0xF8
0x01,0x01,0x03,0x02,0x00,0x64,0x06,0x01,0xB0
0x01,0x00,0x76

If you want to remove 3rd field then use:

cut -d, -f 1,2,4- file

To remove 4th field use:

cut -d, -f 1-3,5- file

edited Dec 14 '20 at 06:25

Jonathan Leffler

730,956
141
904
1,278

answered Dec 14 '20 at 06:19

anubhava

761,203
64
569
643

2

The following is even better for removing the 2nd field, especially when there are many fields: `cut --complement -d, -f2 file` – enharmonic Dec 16 '20 at 16:53

RavinderSingh13 · Accepted Answer · 2020-12-14T05:30:26.620

I believe simplest would be to use sub function to replace first occurrence of continuous ,,(which are getting created after you made 2nd field NULL) with single ,. But this assumes that you don't have any commas in between field values.

awk 'BEGIN{FS=OFS=","}{$2="";sub(/,,/,",");print $0}' Input_file

2nd solution: OR you could use match function to catch regex from first comma to next comma's occurrence and get before and after line of matched string.

awk '
match($0,/,[^,]*,/){
  print substr($0,1,RSTART-1)","substr($0,RSTART+RLENGTH)
}' Input_file

Jonathan Leffler · Answer 3 · 2020-12-14T06:12:23.853

It's a bit heavy-handed, but this moves each field after field 2 down a place, and then changes NF so the unwanted field is not present:

$ awk -F, -v OFS=, '{ for (i = 2; i < NF; i++) $i = $(i+1); NF--; print }' test.txt
0x01,0x93,0x65,0xF8
0x01,0x01,0x03,0x02,0x00,0x64,0x06,0x01
0x01,0x00,0x76
$

Tested with both GNU Awk 4.1.3 and BSD Awk ("awk version 20070501" on macOS Mojave 10.14.6 — don't ask; it frustrates me too, but sometimes employers are not very good at forward thinking). Setting NF may or may not work on older versions of Awk — I was a little surprised it did work, but the surprise was a pleasant one, for a change.

score 3 · Answer 4 · answered Dec 14 '20 at 06:07

If Awk is not an absolute requirement, and the input is indeed as trivial as in your example, sed might be a simpler solution.

sed 's/,[^,]*//' test.txt

This is especially elegant if you want to remove the second field. A more generic approach to remove, the nth field would require you to put in a regex which matches the first n - 1 followed by the nth, then replace that with just the the first n - 1.

So for n = 4 you'd have

sed 's/\([^,]*,[^,]*,[^,]*,\)[^,]*,/\1/' test.txt

or more generally, if your sed dialect understands braces for specifying repetitions

sed 's/\(\([^,]*,\)\{3\}\)[^,]*,/\1/' test.txt

Some sed dialects allow you to lose all those pesky backslashes with an option like -r or -E but again, this is not universally supported or portable.

In case it's not obvious, [^,] matches a single character which is not (newline or) comma; and \1 recalls the text from first parenthesized match (back reference; \2 recalls the second, etc).

Also, this is completely unsuitable for escaped or quoted fields (though I'm not saying it can't be done). Every comma acts as a field separator, no matter what.

The `\n` is not entirely portable, but yeah. – tripleee Dec 14 '20 at 06:39 — tripleee, Dec 14 '20 at 06:39

SLePort · Answer 5 · 2020-12-15T14:30:04.900

2

With GNU sed you can add a number modifier to substitute nth match of non-comma characters followed by comma:

sed -E 's/[^,]*,//2' file

edited Dec 15 '20 at 14:30

answered Dec 14 '20 at 20:31

SLePort

15,211
3
34
44

score 2 · Answer 6 · answered Dec 18 '20 at 01:52

Using awk in a regex-free way, with the option to choose which line will be deleted:

awk '{ col = 2; n = split($0,arr,","); line = ""; for (i = 1; i <= n; i++) line = line ( i == col ? "" : ( line == "" ? "" : ","  ) arr[i] ); print line }' test.txt

Step by step:

{
col = 2    # defines which column will be deleted
n = split($0,arr,",")    # each line is split into an array
                         # n is the number of elements in the array

line = ""     # this will be the new line

for (i = 1; i <= n; i++)   # roaming through all elements in the array
    line = line ( i == col ? "" : ( line == "" ? "" : "," ) arr[i] )
    # appends a comma (except if line is still empty)
    # and the current array element to the line (except when on the selected column)

print line    # prints line
}

score 1 · Answer 7 · edited Dec 14 '20 at 22:48

1

Commenting on the first solution of @RavinderSingh13 using sub() function:

awk 'BEGIN{FS=OFS=","}{$2="";sub(/,,/,",");print $0}' Input_file

The gnu-awk manual: https://www.gnu.org/software/gawk/manual/html_node/Changing-Fields.html

It is important to note that making an assignment to an existing field changes the value of $0 but does not change the value of NF, even when you assign the empty string to a field." (4.4 Changing the Contents of a Field)

So, following the first solution of RavinderSingh13 but without using, in this case,sub() "The field is still there; it just has an empty value, delimited by the two colons":

awk 'BEGIN {FS=OFS=","} {$2="";print $0}' file 
0x01,,0x93,0x65,0xF8
0x01,,0x01,0x03,0x02,0x00,0x64,0x06,0x01,0xB0
0x01,,0x00,0x76

edited Dec 14 '20 at 22:48

grg

5,023
3
34
50

answered Dec 14 '20 at 07:07

Carlos Pascual

1,106
1
5
8

This should probably be a comment on the mentioned answer and perhaps incorporated into an edit! – grg Dec 14 '20 at 22:49
Yes, probably, but I think it's important to know that, which is a general concept. – Carlos Pascual Dec 15 '20 at 07:41

Edward · Answer 8 · 2020-12-15T07:00:04.953

1

My solution:

awk -F, '
{
    regex = "^"$1","$2
    sub(regex, $1, $0);
    print $0;
}'

or one line code: awk -F, '{regex="^"$1","$2;sub(regex, $1, $0);print $0;}' test.txt

I found that OFS="," was not necessary

edited Dec 15 '20 at 07:00

answered Dec 14 '20 at 10:25

Edward

333
2
12

score 1 · Answer 9 · answered Dec 14 '20 at 15:14

1

Another solution:

You can just pipe the output to another sed and squeeze the delimiters.

$ awk -F, 'BEGIN{OFS=","}{$2=""}1 ' edward.txt  | sed 's/,,/,/g'
0x01,0x93,0x65,0xF8
0x01,0x01,0x03,0x02,0x00,0x64,0x06,0x01,0xB0
0x01,0x00,0x76
$

answered Dec 14 '20 at 15:14

stack0114106

8,534
3
13
38

score 0 · Answer 10 · answered Dec 14 '20 at 15:08

I would do it following way, let file.txt content be:

0x01,0xDF,0x93,0x65,0xF8
0x01,0xB0,0x01,0x03,0x02,0x00,0x64,0x06,0x01,0xB0
0x01,0xB2,0x00,0x76

then

awk 'BEGIN{FS=",";OFS=""}{for(i=2;i<=NF;i+=1){$i="," $i};$2="";print}' file.txt

output

0x01,0x93,0x65,0xF8
0x01,0x01,0x03,0x02,0x00,0x64,0x06,0x01,0xB0
0x01,0x00,0x76

Explanation: I set OFS to nothing (empty string), then for 2nd and following column I add , at start. Finally I set what is now comma and value to nothing. Keep in mind this solution would need rework if you wish to remove 1st column.

Can I delete a field in awk?

10 Answers10