Filling list (as an array) : without cut, backtracking leads to infinite recursion after giving a correct production

Question

I need to initialize some lists with a finite number of elements, all the same.

fill( 0, [], _ ) :- !.
fill( Index, [Value|List], Value ) :-
    NextIndex is Index - 1,
    fill( NextIndex, List, Value ).

The cut is mandatory to avoid infinite recursion and a fail result.

I tried to modify the rule #2 but after giving the expected solution, goal fails :

fill( Index, [Value|List], Value ) :-
    Index > 0,
    NextIndex is Index - 1,
    fill( NextIndex, List, Value ).

How it works:

?- fill( 7, AllFalse, false ).
AllFalse = [false, false, false, false, false, false, false].

?-

rajashekar · Answer 1 · 2020-11-15T11:56:00.870

0

eq(X, Y) :- X = Y.
fill(N, Xs, V) :-
    length(Xs, N), maplist(eq(V), Xs).

While this has no external cuts, length/2 has them in generative mode.

You are destructuring a integer value, when checking it's value you always create a choicepoint. If there was a natural number mathematically implemented as follows then you can have a deterministic fill predicate.

nat(0).
nat(suc(X)) :- nat(X).

fill_nat(0, [], _).
fill_nat(suc(N), [V|Xs], V) :-
    fill_nat(N, Xs, V).

?- fill_nat(suc(suc(suc(0))), Xs, a).
Xs = [a, a, a].

edited Nov 15 '20 at 11:56

answered Nov 15 '20 at 11:35

rajashekar

3,460
11
27

suc? It's not succ, rather? – Aubin Nov 15 '20 at 13:23
your choice, just short for `successor`. – rajashekar Nov 15 '20 at 13:24
The first proposal is more complex and hide the cut in the call, it's not a solution. – Aubin Nov 15 '20 at 13:24
I don't think there is a deterministic solution, unless you use something like `nat` above. – rajashekar Nov 15 '20 at 13:26
`length/2` doesn't exactly need cuts, since it is a foreign implemented function but non-logical-ness is from it. – rajashekar Nov 15 '20 at 13:28
Here is its implementation: https://www.swi-prolog.org/pldoc/doc/_SWI_/boot/init.pl?show=src#length/2 – Aubin Nov 15 '20 at 13:30
Let us [continue this discussion in chat](https://chat.stackoverflow.com/rooms/224584/discussion-between-rajashekar-and-aubin). – rajashekar Nov 15 '20 at 13:31

MWB · Answer 2 · 2020-11-16T10:25:58.080

0

I believe this works correctly:

fill(0, [], _).
fill(N, [Val|Tail], Val) :- 
    N > 0,
    N2 is N-1,
    fill(N2, Tail, Val).

(This is equivalent to your second version, and without the cut)

?- fill(2, X, 33).
X = [33, 33] .

?-

but after giving the expected solution, goal fails

It gives you one solution, and if you want more solutions, then it says "there aren't any".

?- fill(2, X, 33).
X = [33, 33] ;
false.

?-

edited Nov 16 '20 at 10:25

answered Nov 15 '20 at 17:41

MWB

11,740
6
46
91

If you trace your code, you will see the backtracking and the fail. – Aubin Nov 15 '20 at 23:55
@Aubin It fails to find **more** solutions. That's why it prints `false`. Why is that a problem? – MWB Nov 16 '20 at 00:28
@Aubin There's no infinite recursion, and no `!`. – MWB Nov 16 '20 at 00:29
When using unit testing a warning is displayed about choice point. – Aubin Nov 16 '20 at 09:31
@Aubin The problem's with the test IMO, but I added another alternative. `maplist` is defined in one of my recent questions. – MWB Nov 16 '20 at 09:58
numlist itself contains a cut. It's not a solution https://www.swi-prolog.org/pldoc/doc/_SWI_/library/lists.pl?show=src#numlist/3 – Aubin Nov 16 '20 at 10:11
@Aubin same as `length` I think. – MWB Nov 16 '20 at 10:21

Filling list (as an array) : without cut, backtracking leads to infinite recursion after giving a correct production

2 Answers2