9

Minimal code:

#!/usr/bin/raku

class Widget {
    submethod TWEAK(:$content, :$styles) {
        say "t1\n";
    }
}

class File is Widget {
    submethod BUILD() {
        say "b1";
    }
}

my $xml = File.new();

And the output:

 t1

 b1

To quote from the relevant doc:

After the BUILD methods have been called, methods named TWEAK are called, if they exist, again with all the named arguments that were passed to new.

So why is TWEAK being hit before BUILD?

I'm using the version of Rakudo that comes with Fedora 32 (rakudo-0.2020.02-1.fc32.x86_64).

cybersam
  • 63,203
  • 6
  • 53
  • 76
Timothy Nelson
  • 565
  • 3
  • 5

2 Answers2

9

A quick experiment adding a TWEAK and BUILD method to each example class where they are missing shows the order of calls is Widget::BUILD -> Widget::TWEAK -> File::BUILD -> File::TWEAK.

So I think the problem is the wording of the documentation "After the BUILD methods have been called, methods named TWEAK are called, if they exist, again with all the named arguments that were passed to new."

I think this should possibly be "After the BUILD methods have been called for each class, methods named TWEAK are called for that class, if they exist, again with all the named arguments that were passed to new."

This would then document what seems to be happening.

Note : since answering this question the documentation has been updated to reflect how the code is being run.

Scimon Proctor
  • 4,558
  • 23
  • 22
  • 1
    Not so sure about that. Note that `Widget`'s `TWEAK` is a `submethod`, so I don't think it should be called at all in this case. – Elizabeth Mattijsen Sep 28 '20 at 14:21
  • 3
    It totally is though. So it's either poor docs or a bug. I've raised a PR on the docs in the assumption it's the first : https://github.com/Raku/doc/pull/3656 I'll leave it to you to decide if it's the second :) – Scimon Proctor Sep 28 '20 at 14:23
  • Indeed. But I hope for more people to decide on this, apart from me. :-) – Elizabeth Mattijsen Sep 28 '20 at 14:26
  • 1
    Well by you I meant you and the steering committee (Which I'm 100% happy to not be on). :) – Scimon Proctor Sep 28 '20 at 14:32
  • 1
    The documentation on https://docs.raku.org/language/objects#Submethods suggests that the submethod _should_ be called, for each parent (at least by the default `new`). Making it a submethod just makes it so that it's not inherited – jja Sep 28 '20 at 15:54
6

TWEAK is called after BUILD.

However, subclasses still need to follow their parents classes' construction routines. Consider the following code:

class Foo {
  submethod TWEAK { say "Foo tweak" }
  submethod BUILD { say "Foo build" }
}

class Bar is Foo {
  submethod TWEAK { say "Bar tweak" }
  submethod BUILD { say "Bar build" }
}

Bar.new

If you run it, you can see what's going on pretty quickly:

Foo build
Foo tweak
Bar build
Bar tweak

Basically, the constructor methods of each class are not called until they've been called for the parent class, meaning at both build and tweak you can assume the parent class' attributes are properly initialized.

This is actually the reason that those methods need to be submethods, otherwise, if a parent class's build method references a private attribute, and the subclass inherits the parents method, you'll get an error since it will be called for both patent and child, but the child won't have access.

user0721090601
  • 5,276
  • 24
  • 41
  • Thanks! That's stupid, but that's Raku's fault, not yours :) . – Timothy Nelson Oct 10 '20 at 03:34
  • 2
    @TimothyNelson While I can understand why someone might want all builds to be called first, in researching it further ( https://github.com/Raku/doc/pull/3656#issuecomment-700133267 ), I found I was mostly correct in why: each class needs to be able to initialize itself without interference from subclasses, otherwise it can potentially be left it in inconsistent state. – user0721090601 Oct 11 '20 at 22:41