How to convert a bash function to a fish function?

Question

Using this post and the documentation, I was trying to create a fish function for a PR on gokechan/lf package to get lfcd working in fish.

This is the bash function that I am trying to convert:

lfcd () {
tmp="$(mktemp)"
lf -last-dir-path="$tmp" "$@"
if [ -f "$tmp" ]; then
    dir="$(cat "$tmp")"
    rm -f "$tmp"
    if [ -d "$dir" ]; then
        if [ "$dir" != "$(pwd)" ]; then
            cd "$dir"
        fi
    fi
fi
}

And this is the fish function I've adapted from the function above:

function lfcd
set tmp "(mktemp)"
lf -last-dir-path="$tmp" "$argv"
if [ -f "$tmp" ];
    set dir "(cat "$tmp")"
    rm -f "$tmp"
    if [ -d "$dir" ];
        if [ "$dir" != "(pwd)" ];
            cd "$dir"
        end
    end
end
end

So far the function runs lf but it does not open the last selected directory on exit.

I have 0 experience creating fish functions or translating bash to fish. This is my introductory fish project, so any help or guidance will be much appreciated!

Don't put fish command substitution in quotes: `set tmp (mktemp)` -- you're setting the tmp variable to the literal string `(mktemp)` — glenn jackman, Sep 15 '20 at 18:16
@glennjackman would the same apply to the line with ```set dir "(cat "$tmp")"``` ? — Jacob Travers, Sep 15 '20 at 22:21
thanks @glennjackman looks like that did the trick, I can make my PR now! — Jacob Travers, Sep 16 '20 at 16:25

score 1 · Answer 1 · answered Sep 16 '20 at 16:43

Most of the time, it's not strictly necessary to quote variables in fish: word splitting is not a feature of fish.

You could write:

function lfcd
    set tmp (mktemp)
    lf -last-dir-path=$tmp $argv
    if [ -f $tmp ]
        set dir (cat $tmp)
        rm -f $tmp
        [ -d $dir ]; and [ $dir != (pwd) ]; and cd $dir
    end
end

How to convert a bash function to a fish function?

1 Answers1