Modelica - iterator with exception?

Question

Slightly generalised example:

How do I make a for loop with exceptions when I define model equations?

The following works:

  model Test
     Real[9] q;
  equation
     q[2] = 1.2;
     q[4] = 1.4; 
     for i in {1,3,5,6,7,8,9} loop
        q[i] = 0;
     end for;
  end Test;

But I would rather like to write something like:

  model Test
     Real[9] q;
  equation
     q[2] = 1.2;
     q[4] = 1.4;
     for i in 1:9 and not in {2,4} loop
        q[i] = 0;
     end for;
  end Test;

Is this possible?

score 5 · Accepted Answer · edited Sep 14 '20 at 12:41

5

This should be possible, as long as you make sure to have an equation for every unknown.

Probably not the perfect solution, but actually pretty readable:

model LoopException
  Real[9] q;
equation 
  q[2] = 1.2;
  q[4] = 1.4; 
  for i in 1:9 loop
    if Modelica.Math.Vectors.find(i, {2, 4}) == 0 then
      q[i] = 0;
    end if;
  end for;
end LoopException;

As an alternative, you could also try to write an "Array Constructor with Iterators" (Modelica Language Spec. Sec. 10.4.1), but that probably gets a bit messy...

edited Sep 14 '20 at 12:41

marco

5,944
10
22

answered Sep 14 '20 at 07:49

Markus A.

6,300
10
26

How to extend this to do the exception not only for a single value "2" but for several values, in a convenient readable way? I update the example to capture this question. – janpeter Sep 14 '20 at 09:05
1

@janpeter: Use `if Modelica.Math.Vectors.find(i, {2, 4}) == 0 then` instead of `if i <> 2 then`. – marco Sep 14 '20 at 09:25
Works fine! Understand that if "I" not found in {2,4} vector then result "0" is given. For more information https://doc.modelica.org/Modelica%203.2.3/Resources/helpDymola/Modelica_Math_Vectors.html – janpeter Sep 14 '20 at 12:33

marco · Answer 2 · 2020-09-14T09:31:44.023

With 2 helper functions you can easily emulate what you want:

model Test
 Real[9] q;
equation
 q[2] = 1.2;
 q[4] = 1.4;
 for i in allExcept(1:9, {2,4}) loop
    q[i] = 0;
 end for;
end Test;

Here are the functions you need for that:

function contains
"Check if vector v contains any element with value e"
  input Integer vec[:];
  input Integer e;
  output Boolean result;
algorithm 
  result := false;
  for v in vec loop
    if v == e then
      result := true;
      break;
    end if;
  end for;
end contains;

function allExcept
  "Return all elements of vector v which are not part of vector ex"
  input Integer all[:];
  input Integer ex[:];
  output Integer vals[size(all, 1) - size(ex, 1)];
protected 
  Integer i=1;
algorithm 
  for v in all loop
    if not contains(ex, v) then
      vals[i] := v;
      i := i + 1;
    end if;
  end for;
end allExcept;

Note that Modelica tools usually need to know the size of vectors during translation, especially here when you generate equations. Hence, the following line is required:

output Integer vals[size(all, 1) - size(ex, 1)];

It will fail when all or ex contain duplicate elements. Therefore the model will not translate, if you try something like

for i in allExcept(1:3, {2, 2}) loop

Modelica - iterator with exception?

2 Answers2