xslt is it ok if we do `select="$position + $jump"`?

Question

I've got this code (which is working properly):

 <xsl:template name="CamelChain">
      <xsl:param name="input"/>
      <xsl:param name="position"/>
      <xsl:if test="$position &lt;= string-length($input)">
         <xsl:choose>
         <xsl:when test="substring($input, $position, 1) = '_'">
            <xsl:value-of select="translate(substring($input, $position + 1, 1), 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>

            <xsl:call-template name="CamelChain">
               <xsl:with-param name="input" select="$input"/>
               <xsl:with-param name="position" select="$position + 2"/>
            </xsl:call-template>
         </xsl:when>

         <xsl:otherwise>

            <xsl:value-of select="substring($input, $position, 1)"/>

            <xsl:call-template name="CamelChain">
               <xsl:with-param name="input" select="$input"/>
               <xsl:with-param name="position" select="$position + 1"/>
            </xsl:call-template>
         </xsl:otherwise>
         </xsl:choose>
      </xsl:if>
   </xsl:template>

And i attempted to normalize it abit as such:

   <xsl:template name="CamelChain">
      <xsl:param name="input"/>
      <xsl:param name="position"/>
      <xsl:if test="$position &lt;= string-length($input)">
         <xsl:choose>
            <xsl:when test="substring($input, $position, 1) = '_'">
               <xsl:value-of select="translate(substring($input, $position + 1, 1), 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
               <xsl:variable name="jump" select="2"/>
            </xsl:when>
            <xsl:otherwise>
               <xsl:value-of select="substring($input, $position, 1)"/>
               <xsl:variable name="jump" select="1"/>
            </xsl:otherwise>
         </xsl:choose>
         <xsl:call-template name="CamelChain">
            <xsl:with-param name="input" select="$input"/>
            <xsl:with-param name="position" select="$position + $jump"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>

But after I've "normalized" it.. it's not working anymore. I suspect its got something to do with the select="$position + $jump" portion but i'm not sure what's wrong with it. does anyone know what's wrong?

Don't say that something "doesn't work". Tell us how it fails. The first thing you need when debugging someone's code is to know the error messages. — Michael Kay, Jun 09 '11 at 11:11
well its working but not working as expected.. so i'd get no error messages — Pacerier, Jun 09 '11 at 16:42

Eric · Answer 1 · 2011-06-09T21:50:38.240

Your problem is that the variable $jump is out of scope. You can't set variables inside a xsl:choose, and expect their value to persist outside. I believe you have to edit the middle section like this:

<xsl:variable name="char" select="substring($input, $position, 1)" />

<xsl:variable name="jump">
    <xsl:choose>
        <xsl:when test="$char = '_'">2</xsl:when>
        <xsl:otherwise>1</xsl:otherwise>
    </xsl:choose>
</xsl:variable>

<xsl:choose>
    <xsl:when test="$char = '_'">
        <xsl:value-of select="translate(substring($input, $position + 1, 1), 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="$char"/>
    </xsl:otherwise>
</xsl:choose>

<xsl:call-template name="CamelChain">
    <xsl:with-param name="input" select="$input"/>
    <xsl:with-param name="position" select="$position + $jump"/>
</xsl:call-template>

The xsl:choose must go within the xsl:variable, not the other way around.

To be honest though, I can't see anything objectionable with your original code. It looks cleaner to me.

well compared to this solution, the `Part 1` code of my question is cleaner of course.. since this repeats the `substring($input, $position, 1)`. However comparing `Part 2` to `Part 1`, part two is way cleaner (well assuming if it did worked of course) — Pacerier, Jun 09 '11 at 16:48
you are missing my point.. `Part 2` is cleaner than `Part 1` because we do not have to repeat `` neither do we have to repeat `` neither do we have to repeat `` (all of which are repeated in `Part 1 Code` ) — Pacerier, Jun 12 '11 at 14:13

score 1 · Accepted Answer · answered Jun 09 '11 at 13:02

1

Your two $jump variables each go out of scope before you reference them.

In XSLT as in any block-structured language a variable has a scope, out of which it is undefined.

    <xsl:when test="substring($input, $position, 1) = '_'">
        <xsl:value-of select=
        "translate(substring($input, $position + 1, 1),
                   'abcdefghijklmnopqrstuvwxyz',
                   'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
        <xsl:variable name="jump" select="2"/>
    </xsl:when>

here you are defining the $jump variable at the very end of its scope and it immediately ceases to exist. This is an obvious error and Some XSLT processors as Saxon even issue a warning message about this.

You have exactly the same problem with the other variable (also named $jump) definition.

answered Jun 09 '11 at 13:02

Dimitre Novatchev

240,661
26
293
431

is it true its scope is everything within its parent. i.e. its children + its siblings? – Pacerier Jun 09 '11 at 16:45
@Pacerier: Yes. I think you'll benefit from reading a good book on XSLT. – Dimitre Novatchev Jun 09 '11 at 16:54
definitely i'd plan to asaic. but right now i'm under pressure to quickly hack some stuff out – Pacerier Jun 09 '11 at 17:24

xslt is it ok if we do `select="$position + $jump"`?

2 Answers2

Linked