19

So, I cannot associate my program with a specific file type without forcing the poor user to enter its admin password (it may be ok for home users, but it is a gigantic problem for users in a corporate env). In this case the only solution is to make the association only for the current user.

I have tried that but something is not working.

If i understand correctly I have to write a key like (let's say) '.mp3' in ctCurUserFileExt and write in it something like 'my_file'. Then in ctCurUserClases I add a key like this: 

WriteReg_String(RootKey, ctCurUserClases+ 'my_file\shell\open\command', '', Application.ExeName+ ' "%L"', TRUE)

However, when I double click the file, Windows asks me with which application should it open it.

Here are the constant:

CONST
     RootKey= 'HKEY_CURRENT_USER';
     ctCurUserFileExt= '\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\';
     ctCurUserClases = '\Software\Classes\';
Gabriel
  • 20,797
  • 27
  • 159
  • 293

2 Answers2

24

If you want to register the association for every user, write your data to

HKEY_LOCAL_MACHINE\Software\Classes

If you want to register the association for the current user only, write your data to

HKEY_CURRENT_USER\Software\Classes

This is how to do the latter:

with TRegistry.Create do
  try
    RootKey := HKEY_CURRENT_USER;
    if OpenKey('\Software\Classes\.myfile', true) then
      WriteString('', 'MyAppDataFile');
    if OpenKey('\Software\Classes\MyAppDataFile', true) then
      WriteString('', 'My Very Own Text File Type');
    if OpenKey('\Software\Classes\MyAppDataFile\DefaultIcon', true) then
      WriteString('', 'C:\WINDOWS\notepad.exe');
    if OpenKey('\Software\Classes\MyAppDataFile\shell\open\command', true) then
      WriteString('', 'C:\WINDOWS\notepad.exe "%1"');
  finally
    Free;
  end;
SHChangeNotify(SHCNE_ASSOCCHANGED, SHCNF_IDLIST, 0, 0);

This will associate .myfile files, called "My Very Own Text File Type" so that they will have the icon of notepad.exe and will be opened by notepad.exe. The last line tells Explorer to 'reload' itself to reflect the changes made to the file associations. For instance, Explorer file list views will update. The WinAPI function SHChangeNotify is declared in ShlObj.pas, so you need to uses ShlObj.

Notice that the %1 in shell\open\command will expand to the current file. For instance, if you double-click on C:\some dir\test.myfile, then Explorer will execute the command

C:\WINDOWS\notepad.exe "C:\some dir\test.myfile"
Andreas Rejbrand
  • 105,602
  • 8
  • 282
  • 384
  • So, I had to add both entries in ctCurUserClases ? I thought I need to add one in ctCurUserClases and one in ctCurUserFileExt. – Gabriel Jun 08 '11 at 22:18
  • 1
    @Altar: HKCR is a merged view of both HKLM and HKCU together. The view is initialized with default values from HKLM, and then HKCU values are placed on top of that. Read MSDN for more details: http://msdn.microsoft.com/en-us/library/ms724475.aspx and http://msdn.microsoft.com/en-us/library/ms724498.aspx. – Remy Lebeau Jun 10 '11 at 21:13
  • I see that most programs are using %L instead of %1. What it the difference? – Gabriel Jun 13 '11 at 12:15
  • @Altar: I have never seen %L, but %1 has always been used for this purpose. I suspect you are mixing them up. – Andreas Rejbrand Jun 13 '11 at 12:19
  • 1
    Free library DSiWin32 (http://gpdelphiunits.googlecode.com/svn/trunk/src/DSiWin32.pas) now implements this as DSiRegisterUserFileAssoc and DSiUnregisterUserFileAssoc. – gabr Jul 24 '14 at 13:26
  • What does `'MyAppDataFile'` mean? Can you provide a practical usage example? – user1580348 May 09 '21 at 20:04
  • @user1580348: That's just an internal name for the file type. The first key says that `.myfile` is of type `MyAppDataFile`, and the remaining three keys gives the name, icon, and application for such a file. In practice, `MyAppDataFile` could be `ContosoRichTextFile` or `LitwareVideoFile` or `SuperappSettingsFile`. – Andreas Rejbrand May 09 '21 at 21:28
  • It it possible to do registry manipulation to achieve this using powershell? – Alexandros Dec 08 '21 at 16:23
  • @Alexandros: Yes, that is certainly possible. – Andreas Rejbrand Dec 08 '21 at 16:30
2

Have you looked at setting it under HKEY_CURRENT_USER\Software\Classes as per http://support.microsoft.com/kb/257592

BugFinder
  • 17,474
  • 4
  • 36
  • 51
  • It works exactly like setting it globally, except there is the user specific place to put the keys to get the file associations. – BugFinder Jun 09 '11 at 05:24