3

I am trying to visualize a time series data set on one plot as a pseudo 3d figure. However, I am having some trouble getting the filledcurves capability working properly. It seems to be adding an unwanted border at the "bottom" of my functions and I do not know how to fix this.

This is my current set up: I have nb_of_frames different files that I want to plot on one figure. Without the filledcurves option, I can do something like this 

plot for [i=1:nb_of_frames] filename(i) u ($1):(50.0 * $2 + (11.0 - (i-1)*time_step)) w l linewidth 1.2 lt rgb "black" notitle

which produces a figure like this: no fill options

enter image description here

Instead of doing this, I want to use the filledcurves option to bring my plots "forward" and highlight the function that is more "forward" which I try to do with:

plot for [i=1:nb_of_frames] filename(i) u ($1):(50. * $2 + (11. - (i-1)*time_step)) w filledcurves fc "white" fs solid 1.0 border lc "black" notitle

This produces a figure as follows: enter image description here

This is very close to what I want, but it seems that the border option adds a line underneath the function which I do not want. I have tried several variants of with filledcurves y1=0.0 with different values of y1, but nothing seems to work.

Any help would be appreciated. Thank you for your time.

theozh
  • 22,244
  • 5
  • 28
  • 72
Eric Tovar
  • 33
  • 3

2 Answers2

2

I can reproduce this in gnuplot 5.2.8 but not in the output from the release candidate for version 5.4. So I think that some bug-fix or change was applied during the past year or so. I realize that doesn't help while you are using verion 5.2, but if you can download and build from source for the 5.4 release candidate that would take care of it.

enter image description here

Update I thought of a work-around, although it may be too complicated to be worth it. You can treat this as a 2D projection of a 3D fence plot constructed using plot style with zerrorfill. In this projection the y coordinate is the visual depth. X is X. Three quantities are needed on z: the bounding line, the bottom, and the top. I.e. 5 fields in the using clause: x depth zline zbase ztop.

unset key
set view 90, 180
set xyplane at 0
unset ytics

set title "3D projection into the xz plane\nplot with zerrorfill" offset 0,-2

set xlabel "X axis" offset 0,-1
set zlabel "Z"

splot for [i=1:25] 'foo.dat' using ($1+i):(i/100.):($2-i):(-i):($2-i) \
                    with zerrorfill fc "light-cyan" lc "black"  lw 2

enter image description here

Ethan
  • 13,715
  • 2
  • 12
  • 21
  • Hi Ethan, thank you for your reply. I am currently on version 5.2. I seem to have found a "work around" but I am having some trouble getting the script to work properly. This is the "algorithm": 1. plot the step function seen in first figure 2. add the white filled curve for first file (top most function) 3. manually add the border 4. repeat for rest of files This is very messy and it would be neat to get in a loop somehow. I am not aware of how to do multiple commands in a `plot for [I:nb_of_frames] etc`. – Eric Tovar Jun 15 '20 at 00:52
  • Because the order is important here, it would great if I could do something like ``` plot "bath.plt" u ($1):($2 * 50.0) w l lt rgb "black" lw 2 notitle, \ for [i=1:nb_of_frames] filename(i) u ($1):(50. * $2 + (11. - (i-1)*time_step)) w filledcurves y1=7. fs solid 1.0 border lc "black" notitle, filename(i) u ($1):(50. * $2 + (11. - (i-1)*time_step)) w l lt rgb "black" lw 1.2 notitle ``` where the for loop is doing two commands. – Eric Tovar Jun 15 '20 at 01:04
  • I found a work-around for gnuplot 5.2 (tested using 5.2.8). See updated answer. – Ethan Jun 15 '20 at 05:46
2

Here is another workaround for gnuplot 5.2.

Apparently, gnuplot closes the filled area from the last point back to the first point. Hence, if you specifiy border, then this line will also have a border which is undesired here (at least until gnuplot 5.4rc2 as @Ethan says).

A straightforward solution would be to plot the data with filledcurves without border and then again with lines. However, since this is a series of shifted data, this has to be plotted alternately. Unfortunately, gnuplot cannot switch plotting styles within a for loop (at least I don't know how). As a workaround for this, you have to build your plot command in a previous loop and use it with a macro @ (check help macros) in the plot command. I hope you can adapt the example below to your needs.

Code:

### filledcurves without bottom border
reset session
set colorsequence classic

$Data <<EOD
1  0
2  1
3  2
4  1
5  4
6  5
7  2
8  1
9  0
EOD

myData(i) = sprintf('$Data u ($1-0.1*%d):($2+%d/5.)',i,i)
myFill    = ' w filledcurves fc "0xffdddd" fs solid 1 notitle'
myLine    = ' w l lc rgb "black" notitle'

myPlotCmd = ''
do for [i=11:1:-1] {
    myPlotCmd = myPlotCmd.myData(i).myFill.", ".myData(i).myLine.", "
}

plot @myPlotCmd

### end of code

Result:

enter image description here

theozh
  • 22,244
  • 5
  • 28
  • 72
  • Thank you @theozh!!! This was very easy to adapt to my setting and I was able to get it working quickly. I appreciate your help and yours as well @Ethan! – Eric Tovar Jun 15 '20 at 14:49