8

I want to add interactivity to Mathematica 3D graphics, other than with Manipulate which is cool but has its limitations. Think four example of a demo of the four cubes problem in Mathematica, a click on one of the cubes rotates a cube.

Questions.

  1. Is it possible to catch MouseEvents in Mathematica graphics ( for example with using a Java class or otherwise? )

  2. Or is the use Java then call Mathematica from Java the advised route?

  3. Or ( I hope not ) is developing interactive graphics programs beyond of what one should do with Mathematica?

nilo de roock
  • 4,077
  • 4
  • 34
  • 62

1 Answers1

15

EventHandler can be used to catch various mouse events (mouse up, mouse down, mouse clicked, mouse dragged). Use MousePosition to add some intelligence.

Example:

DynamicModule[{col1 = Green, col2 = Blue}, Graphics[
  {
   EventHandler[
    Dynamic[{col1, Disk[]}, 
     ImageSize -> 
      Tiny], {"MouseClicked" :> (col1 = 
        col1 /. {Red -> Green, Green -> Red})}],
   EventHandler[
    Dynamic[{col2, Disk[{1, 1}]}, 
     ImageSize -> 
      Tiny], {"MouseClicked" :> (col2 = 
        col2 /. {Blue -> Yellow, Yellow -> Blue})}]
   }
  ]
 ]

enter image description here

The circles can be clicked independently. An action is defined for each object separately.

Amazingly, this even works for 3D Graphics:

DynamicModule[{col1 = Green, col2 = Blue}, 
 Graphics3D[
  {
   EventHandler[
    Dynamic[{col1, Sphere[]}, 
     ImageSize -> 
      Tiny], {"MouseClicked" :> (col1 = 
        col1 /. {Red -> Green, Green -> Red})}], 
   EventHandler[
    Dynamic[{col2, Sphere[{1, 1, 1}]}, 
     ImageSize -> 
      Tiny], {"MouseClicked" :> (col2 = 
        col2 /. {Blue -> Yellow, Yellow -> Blue})}]
   }
  ]
 ]

enter image description here

Sjoerd C. de Vries
  • 16,122
  • 3
  • 42
  • 94
  • 2
    @ndroock1 Thanks for accepting my answer. Next time you might wait a little longer so as to get more responses. – Sjoerd C. de Vries May 31 '11 at 15:49
  • 2
    Sjoerd, I already voted for this, but I would vote again for the update. I've never seen that before, rotatable and all. :-) – Mr.Wizard May 31 '11 at 22:51
  • Why does the mouse tip, in the 3D case, do not pick a little arrow shape as would would expect when wanting to click on things? in the 2D example shown above, the tooltip at the end of the mouse on the screen is a little arrow, but not in the 3D case. This is a little confusing to the user I think. – Nasser Jun 01 '11 at 03:02
  • @Nasser Nobody is perfect, I guess. – Sjoerd C. de Vries Jun 01 '11 at 05:49
  • @Sjoerd, It is nice to see that Mathematica still amazes you at times. – nilo de roock Jun 01 '11 at 09:00