3

In short, I need to start 1.bat, that can CALL or START 2.bat to execute TASKKILL /im explorer.exe /f /t but keeps "1.bat" running (or reopens it) once "2.bat" is finished. The difficulty is, I need to keep the /t switch in TASKKILL to make it transferable.

Full Explanation:
I have several older laptops running Windows 7 x64. They will run games, but only if I use Task Manager to end Explorer, it's associated processes and stop several unneeded services. This frees up RAM and CPU to start games via Task Manager..

To avoid ending each process/service individually every time, I wrote 2 cmd batch files:

1) Options.bat -- (SHORTENED)

@echo off
:begin
echo (0) Kill Processes
echo (1) Run [game]
SET /p op=Select Task:
if "%op%"=="0" goto killall
if "%op%"=="1" goto op1
killall:
CALL "C:\TK.bat"
cls
goto begin
op1:
start " " /realtime "C:\[exe path]"
goto exit
:exit
exit

2) TK.bat -- (SHORTENED)

net stop [service]
taskkill /im explorer.exe /f /t
taskkill /im [specific process].exe /f /t

Both of which work as intended - provided I initially start Options.bat via Task Manager.

Problem: when I run Options.bat from Windows Explorer (even "Run As Administrator") and call the TK.bat script to run TASKKILL /im explorer.exe /f /t it does work, but also closes the CMD window, when i want it to return to the options selection. This does make sense when i'm using the "tree" attribute for TASKKILL.

However, if I run Options.bat via Task Manager, and CALL TK.bat, it will execute the commands (without closing itself) then return to the task selection - which is exactly what i want to happen!
I assume this is because it is running as the Local System account via Task Manager and not mine or the built in Administrator account?

I have tried the RUNAS command within Options.bat - 

RUNAS /user:Adminstrator "C:\TK.bat"

which runs TK.bat, executes the TASKKILL command and then RUNAS again to return to the first batch file in my username. This does work, but I still have to press enter at each password prompt.

I have also tried numerous variations of the TASKKILL /FI switch:

TASKKILL /fi IMAGENAME ne cmd.exe /im explorer.exe /f /t`
TASKKILL /fi USERNAME eq [name] /fi WINDOWTITLE ne Options.bat /im explorer.exe /f /t

Which, I thought, would end all processes "not equal" to cmd.exe/Options.bat but I cannot get it to work.

Question: Is there a way of executing the TASKKILL /im explorer.exe /f /t within TK.bat, that will not close the currently running batch file and without having to run it from Task Manager? Perhaps a different command or giving the Options.bat some sort of elevated authority to stop it from being closed when Explorer.exe /t is ended. Ideally, without installing separate 3rd party tools?

I know I could edit the batch file to end explorer.exe, end each associated .exe and then stop the services I do not need, individually, but this is time consuming and defeats the point of writing the file to make it automated and transferable (if needed).

Any help would be greatly appreciated and I can upload the full code of both batch files, if that would help.

Ardent Coder
  • 3,777
  • 9
  • 27
  • 53
G89
  • 31
  • 1
  • 2

2 Answers2

2

Strangely enough, the simple taskkill /F /IM explorer.exe & start explorer command does this task. I don't know why, but it works.

Nico Nekoru
  • 2,840
  • 2
  • 17
  • 38
  • It appears to work but actually it does't. When you do `taskkill /F /IM explorer.exe & start explorer` all of the processes which where child of the `exeplorer.exe` will remain alive and the newly created `exeplorer.exe` process will not be the parent of those processes, so now issuing `taskkill /im explorer.exe /f /t` wont kill them. It defeats the purpose of the OP's question which it to kill the child processes along with `exeplorer.exe` but to keep the one that is running the batch file. – sst May 17 '20 at 08:12
0

To prevent taskkill /im explorer.exe /f /t from killing the cmd instance which is executing your batch file, You need to break the parent-child relationship between that particular instance of cmd.exe and explorer.exe.

The trick is to use two extra instances of nested cmds. The first one launches the second one and terminates immediately so the second instance becomes an orphaned process which can not be determined as descendant of exeplorer.exe. At this point the second instance can safely execute taskkill /im explorer.exe /f /t

start "Chain breaker" /min cmd /d /c start "Orphaned Process" cmd /d /c Options.bat

The above can be used from Command Prompt or from another batch file.

You can also incorporate this technique directly in to the Options.bat file, But extra logic is needed for Options.bat to determine when to launch itself in nested cmd and when to execute the actual code.

A sample script demonstrating the concept would be:

@echo off
setlocal EnableExtensions DisableDelayedExpansion
for /F "tokens=3 delims=:" %%L in ("%~0") do goto %%L

REM Reinvoke the batch file forcing it to jump to the :main label
start "Chain breaker" /min cmd /d /c start "Orphaned Process" cmd /d /c @"%~d0\:main:\..%~pnx0"
exit /b

:main
taskkill /im explorer.exe /f /t
echo I'm alive
pause
exit /b
sst
  • 1,443
  • 1
  • 12
  • 15