Create a Function for Customized Tabular Representation

Question

I use the code below get an overview of parts of my data.

What would be the best way to make a function out of the below code ?

It would take a dataList as well as some graphical options (such as colors) as arguments and return a customized tabular representation as shown below.

overviewtheData=Text@Grid[{Map[Rotate[Text[#],
90Degree]&,data[[1]]]}~Join~data[[2;;]],
Background->{{{{White,Pink}},{1->White}}},
Dividers->{All,{1->True,2->True,0->True}},
ItemSize->{1->5,Automatic},
Alignment->Top,
Frame->True,
FrameStyle->Thickness[2],
ItemStyle->{Automatic,Automatic,{{1,1},
{1,Length@data[[1]]}}->Directive[FontSize->15,Black,Bold]}]

enter image description here

I wouldn't describe the above as a _graphical_ representation. It's a _tabular_ representation... I find the question a bit unclear, could you try to rephrase it? — Sjoerd C. de Vries, May 28 '11 at 08:57
It would be better to correct the title too: the question is not related to `Graphics` in *Mathematica*'s sense. — Alexey Popkov, May 28 '11 at 12:12

score 7 · Accepted Answer · edited Jun 20 '20 at 09:12

Belisarius gave the basic method. I shall introduce an advanced method, because you seem eager to learn.

First let me say that I saw what I believed were simplifications to your code, and I made them, hopefully not in error.

I will use this sample data in illustrations below:

data = Prepend[
         RandomInteger[99, {5, 12}], 
         DateString[{1, #}, "MonthName"] & /@ Range@12
       ];

Goals

Since the main function used is Grid it makes sense to allow passing options to it.
You have a series of options that define your table. I want to be able to conveniently change these.
I want the possibility of custom options not understood by Grid.

Implementation

Goal #1

An argument pattern opts:OptionsPattern[] is added, which matches any sequence of Option -> Setting arguments, and names it opts. (See: OptionsPattern for more.) Then, opts is inserted into the basic function before the other options for Grid. This allows any explicitly given options to override the defaults, or new ones to be given.

customTabular[data_, opts : OptionsPattern[]] :=
  Grid[MapAt[Rotate[#, 90 Degree] & /@ # &, data, 1],
   opts,
   Background -> {{{White, Pink}}},
   Dividers -> {All, {2 -> True}},
   ItemSize -> {1 -> 5},
   Alignment -> {Center, {1 -> Top}},
   Frame -> True,
   FrameStyle -> Thickness[2],
   ItemStyle -> Directive[FontSize -> 15, Black, Bold]
  ] // Text

Examples:

customTabular[data]

enter image description here

customTabular[data, Background -> LightBlue]

enter image description here

Goal #2

The options that define your tabular format can be separated from the function body. This will allow them to be conveniently changed or referenced. I start by clearing the previous definition with ClearAll. Then I set default Options for customTabular:

ClearAll[customTabular]

Options[customTabular] =
  {Background -> {{{White, Pink}}},
   Dividers -> {All, {2 -> True}},
   ItemSize -> {1 -> 5},
   Alignment -> {Center, {1 -> Top}},
   Frame -> True,
   FrameStyle -> Thickness[2],
   ItemStyle -> Directive[FontSize -> 15, Black, Bold]};

Now the function proper. Here Options@customTabular gets the rules given above.

customTabular[data_, opts : OptionsPattern[]] := 
 Grid[MapAt[Rotate[#, 90 Degree] & /@ # &, data, 1],
   opts, 
   Sequence @@ Options@customTabular
 ] // Text

Now you can easily change the defaults with SetOptions. Example:

SetOptions[customTabular, 
  Background -> {{{LightMagenta, LightOrange}}}
];

customTabular[data]

enter image description here

Goal #3

Now I want to add an option that is not passed to Grid. I choose "Rotation" to change the text rotation of the title row.

Again I clear the prior definition and the default options. Notice the inclusion of "Rotation" -> 90 Degree in the list.

ClearAll[customTabular]

Options[customTabular] =
  {Background -> {{{White, Pink}}},
   Dividers -> {All, {2 -> True}},
   ItemSize -> {1 -> 5},
   Alignment -> {Center, {1 -> Top}},
   Frame -> True,
   FrameStyle -> Thickness[2],
   ItemStyle -> Directive[FontSize -> 15, Black, Bold],
   "Rotation" -> 90 Degree};

Now I need a way to use this new option, and I need a way to keep this option from being sent to Grid:

I access the option with OptionValue which will give the default if none is explicitly given.
I pass only valid Grid options by using FilterRules.

I first join any explicit options to the front of the Options@customTabular list, again to override defaults.

customTabular[data_, opts : OptionsPattern[]] :=
 Grid[MapAt[Rotate[#, OptionValue["Rotation"]] & /@ # &, data, 1],
   Sequence @@ FilterRules[{opts} ~Join~ Options@customTabular, Options@Grid]
 ] // Text

Example:

SetOptions[customTabular, Background -> {{{LightBrown, LightYellow}}}];

customTabular[data,
  Dividers -> All,
  "Rotation" -> -90 Degree,
  FrameStyle -> {Darker@Red, Thick}
]

enter image description here

Very nice! Shows the design process, not just the result. +1 — Leonid Shifrin, May 28 '11 at 20:43
@Mr.Wizard Nothing much comes to mind. If you *really* want this to be maximally didactic (it is didactic already), you could may be put references / links to the documentation for things like `OptionsPattern` and `FilterRules`, and a few links to some places where options mechanism is discussed. — Leonid Shifrin, May 28 '11 at 20:57
@d00b Thanks! I am learning from Leonid how to give good answers. — Mr.Wizard, May 29 '11 at 22:23
@Leonid, I noticed that for `Grid` my use of `Sequence @@` is superfluous. Is this true more generally? `OptionsPattern[]` matches rules in or out of lists; is it safe to assume that most functions accept options given like: `f[1, 2, op1 -> val, op2 -> val, {op3 -> val, op4 -> val}]`? — Mr.Wizard, May 30 '11 at 08:22
@Mr.Wizard Nope, it is not safe (IMO). The problem is that when you pass options more than once, you may accumulate the depth of the rule list. And since rules at depth more than one in a (nested) list are not interpreted as options, you may run into trouble. And in any case, I would not count on that - this does not look for me like a good case for saving a few keystrokes. Just my two cents... — Leonid Shifrin, May 30 '11 at 08:27
@Mr.Wizard Oh, by the way, congrats with the Mathematica silver badge! — Leonid Shifrin, May 30 '11 at 08:34
@Leonid, I knew you would have some advice. I always use `Sequence` in this way, and I suspect for a reason, but I wanted to make sure that reason wasn't antiquated. Re: the badge, thank you! :D — Mr.Wizard, May 30 '11 at 08:58

score 4 · Answer 2 · answered May 28 '11 at 04:49

I'd do it the usual way

f[data_, color1_, color2_] := 
 Text@Grid[{Map[Rotate[Text[#], 90 Degree] &, data[[1]]]}~Join~
    data[[2 ;;]], Background -> {{{{color1, color2}}, {1 -> color1}}},
    Dividers -> {All, {1 -> True, 2 -> True, 0 -> True}},
    ItemSize -> {1 -> 5, Automatic}, Alignment -> Top, Frame -> True, 
    FrameStyle -> Thickness[2], 
    ItemStyle -> {Automatic, Automatic, {{1, 1}, {1, Length@data[[1]]}} -> 
                               Directive[FontSize -> 15, Black, Bold]}]

f[{{t1, t2, t3}, {1, 2, 3}, {4, 5, 6}}, LightBlue, Orange]

enter image description here

I am not sure what you are trying to ask for in the last part such a graph as an output ...

Create a Function for Customized Tabular Representation

2 Answers2

Goals

Implementation

Goal #1

Goal #2

Goal #3

Linked